1 !
3 ! EXELVISION EXL 100
5 !
7 ! EXELABYRINTHE
9 !
11 ! PAR
13 ! ALAIN BARBIER
15 CLS "BGb":CALL COLOR("0BG")
17 LOCATE (3,8):PRINT "PROGRAMME EXELABYRINTHE":LOCATE (5,17)
19 PRINT "ECRIT":LOCATE (7,11):PRINT "POUR VOTRE PLAISIR":LOCATE (9,9)
21 PRINT "POUR EPROUVER VOS NERFS,":LOCATE (11,5)
23 PRINT "VOTRE SANG-FROID,VOTRE MEMOIRE":LOCATE (13,5)
25 PRINT "ET VOTRE SENS DE L'ORIENTATION"
27 CALL COLOR(0bGLH"): LOCATE (17,11): PRINT "AALLAAIINN BBAARRBBIIEERR"
29 LOCATE (18,7): PRINT "AALLAAIINN BBAARRBBIIEERR"
31 K=50688:RESTORE 35:FOR A=1 TO 7:READ L$:GOSUB 671:NEXT:CALL EXEC(50688)
33 K=50888:RESTORE 539:FOR A=1 TO 4:READ L$:GOSUB 671:NEXT
35 DATA "984F0A780B0A790009FB0A","A43624233C92B0C6D2F0344FCC5ACBDCCD2289EA120F"
37 DATA "E550BB254FAA93951A9538AB1815CE9C5C2FAB0DC36631BC18172E5B450F6A5CB86C15"
39 DATA "33A82A2277599CE0C389D27609B23417363B259BCA9C95EDB46ABA0C5721DDEAA53345"
41 DATA "844AA9BA325774A7A50CC6D5DCD2942AF2364AED9CEA609BD9E45168BD6A519525AEF7"
43 DATA "BA5585179B31C851325E6326AF46D964919ABC1A6393D96A72AECCC4569939B83251B9"
45 DATA "65E6E82A446C25025863464008A508883AEDFF01"
47 PAUSE 4:CLS "bMb"
49 CALL CHAR(39,"00103070FF703010")
51 CALL CHAR(40,"00080C0EFF0E0C08")
53 CALL CHAR(41,"00081C3E7F08080808")
55 CALL CHAR(42,"00080808087F3E1C08")
57 CALL COLOR("0bMLHF")
59 LOCATE (11,7):PRINT "EEXXEELLAABBYYRRIINNTTHHEE":LOCATE (12,7)
61 PRINT "EEXXEELLAABBYYRRIINNTTHHEE":PAUSE 2:CALL COLOR("0WM"):LOCATE (18,9)
63 PRINT "SUIVEZ LES INSTRUCTIONS"
65 L$="VOUS POURREZ UTILISER LES TOUCHES...":GOSUB 485
67 CALL COLOR("0MM"):LOCATE (18,9):PRINT RPT$(" ",23)
69 LOCATE (18,20):CALL COLOR("1BW"):PRINT CHR$(40)
71 L$=" DEPLACEMENT A DROITE ":GOSUB 485
73 LOCATE (18,20):CALL COLOR("1BW"):PRINT CHR$(39)
75 L$=" DEPLACEMENT A GAUCHE ":GOSUB 485
77 LOCATE (18,20):CALL COLOR("1BW"):PRINT CHR$(41)
79 L$=" DEPLACEMENT TOUT DROIT ":GOSUB 485
81 LOCATE (18,20):CALL COLOR("1BW"):PRINT CHR$(42)
83 L$=" MARCHE ARRIERE ":GOSUB 485
85 CALL COLOR("0MM"):LOCATE (18,20):PRINT " "
87 L$=" BARRE D'ESPACEMENT POUR TIRER ":GOSUB 485
89 CALL COLOR("0BW"):LOCATE (18,19):PRINT "ESC"
91 L$=" ESCape POUR RECOMMENCER A ZERO ":GOSUB 485
93 !
95 ! CARACTERES SPECIAUX
97 !
99 CALL CHAR(1,"230D35474B1122240808")
101 CALL CHAR(2,"C3FE7B3160F84C8780")
103 CALL CHAR(3,"E2BFFF4701A5EEF9")
105 CALL CHAR(4,"E8F4E2E2C2B010109080")
107 CALL CHAR(5,"0000001F2120200D1126")
109 CALL CHAR(6,"182442071FFFA1E1E141")
111 CALL CHAR(7,"40A48AF0FDFD8D8687E7")
113 CALL CHAR(8,"18244282000C92E18160")
115 CALL CHAR(9,"3049072F5999A79E2310")
117 CALL CHAR(10,"844A11E0343AF169C404")
119 CALL CHAR(11,"001C3C634141633C1C")
121 CALL CHAR(12,"00000000FFFF")
123 CALL CHAR(13,"00000000FEFE745444")
125 CALL CHAR(14,"00021F083F35717F70")
127 CALL CHAR(15,"0000FF10F8")
129 CALL CHAR(16,"0002FE")
131 CALL CHAR(17,"00797B636363637B79")
133 CALL CHAR(18,"00E7F736363636F7E7")
135 CALL CHAR(19,"009EDED8DCDCD8DE9E")
137 CALL CHAR(20,"FF")
139 CALL CHAR(21,"000103070F0F1F3F7FFF")
141 CALL CHAR(22,"0080C0E0F0F0F8FCFEFF")
143 CALL CHAR(23,"0001010303070F0F1F1F")
145 CALL CHAR(24,"008080C0C0E0F0F0F8F8")
147 CALL CHAR(25,"00000000000001010303")
149 CALL CHAR(26,"3F3F7F7FFFFFFFFFFFFF")
151 CALL CHAR(27,"FCFCFEFEFFFFFFFFFFFF")
153 CALL CHAR(28,"0000000000008080C0C0")
155 CALL CHAR(29,"07070F0F1F3F3F7F7FFF")
157 CALL CHAR(30,"E0E0F0F0F8FCFCFEFEFF")
159 CALL CHAR(31,"000002060E0E1E3E7EFE")
161 CALL CHAR(33,"000040607070787C7E7F")
163 CALL CHAR(34,"FEFEFEFEFEFEFEFEFEFE")
165 CALL CHAR(35,"7F7F7F7F7F7F7F7F7F7F")
167 CALL CHAR(36,"FFFFFFFFFF")
169 CALL CHAR(37,"FFC3810000000081C3C3")
171 CALL CHAR(38,"C3C3C3C3C3C3C3FFFFFF")
173 !
175 ! PROGRAMME
177 !
179 DIM Z$(27,27)
181 CLS "bGb":CALL COLOR("0GbILH"):LOCATE (4,1)
183 PRINT "CCHHOOIIXX DDUU LLAABBYYRRIINNTTHHEE":LOCATE (5,1)
185 PRINT "CCHHOOIIXX DDUU LLAABBYYRRIINNTTHHEE":LOCATE (9,1)
187 PRINT " 11--PPEETTIITT ,, 22--GGRRAANNDD":LOCATE (10,1)
189 PRINT " 11--PPEETTIITT ,, 22--GGRRAANNDD":LOCATE (14,1)
191 PRINT " 33--":LOCATE (15,1):PRINT " 33--":CALL COLOR("0GbIH")
193 LOCATE (14,7):PRINT " DEMONSTRATION AUTOMATIQUE":LOCATE (15,7)
195 PRINT " DEMONSTRATION AUTOMATIQUE":LOCATE (17,1)
197 PRINT " AU COEUR DU GRAND LABYRINTHE":LOCATE (18,1)
199 PRINT " AU COEUR DU GRAND LABYRINTHE"
201 CH$=KEY$:CH=ASC(CH$)
203 IF CH<49 OR CH>51 THEN 201
205 IF CH=49 THEN MX=41:RESTORE 337:GOTO 209
207 IF CH=50 OR CH=51 THEN RESTORE 309:MX=65:NO=0
209 FOR I=1 TO MX:READ L$:E=ASC(SEG$(L$,1,1))-48
211 F=ASC(SEG$(L$,2,1))-48:Z$(E,F)=SEG$(L$,3,8):NEXT:A,B,C=0:E=2:F=1
213 L$="SI VOUS PASSEZ LA PREMIERE PORTE...":CLS "BGG":GOSUB 485
215 L$="VOUS SEREZ ENFERME DANS UN LABYRINTHE":CLS "BRR":GOSUB 485
217 L$="A VOUS D'EN SORTIR,HAHAHAHA...":CLS "BMM":GOSUB 485:GOSUB 399
219 IF CH=51 THEN GOSUB 685 ELSE I=ASC(KEY$):IF I=27 THEN 179
221 IF I=128 OR I=129 OR I=130 OR I=131 THEN 223 ELSE 219
223 I=2*I-255:TCH=I:G=ASC(SEG$(Z$(E,F),I+1,1))-48:FIG=ASC(SEG$(Z$(E,F),I,1))-48
225 IF FIG=0 THEN L$="CHOISISSEZ UNE DIRECTION POSSIBLE":GOSUB 485:GOTO 219
227 IF FIG=11 THEN L$="CECI EST UNE ILLUSION":GOSUB 485:FIG=4
229 IF FIG=12 THEN L$="CECI EST UNE ILLUSION":GOSUB 485:FIG=2
231 IF FIG=13 AND C=0 THEN L$="VOUS TROUVEZ UNE CLEF":CLS:GOSUB 485:C=1:FIG=4
233 IF FIG=13 AND C=1 THEN FIG=4
235 IF FIG=14 AND C=1 THEN L$="ICI ON PERD SES CLEFS":CLS "BWW":GOSUB 485:C=0
237 IF FIG=14 THEN FIG=3
239 IF FIG=15 AND C=1 THEN L$="ICI ON PERD SES CLEFS":CLS "BWW":GOSUB 485:C=0
241 IF FIG=15 THEN FIG=4
243 IF FIG=17 AND B=0 THEN L$="VOUS TROUVEZ UNE ARME":CLS:GOSUB 485:B=1:FIG=3
245 IF FIG=16 AND B=0 THEN L$="VOUS TROUVEZ UNE ARME":CLS:GOSUB 485:B=1:FIG=2
247 IF FIG=16 AND B=1 THEN FIG=2
249 IF FIG=17 AND B=1 THEN FIG=4
251 IF FIG=18 AND A=1 THEN FIG=2
253 IF FIG=18 AND A=0 THEN L$="VOUS TROUVEZ UN CODE":CLS:GOSUB 485:A=1:FIG=2
255 IF FIG=19 AND A=1 THEN FIG=3
257 IF FIG=19 AND A=0 THEN L$="VOUS TROUVEZ UN CODE":CLS:GOSUB 485:A=1:FIG=3
259 IF (FIG=20 OR FIG=21)AND C=0 THEN L$="IL FAUT UNE CLEF":GOSUB 485:GOTO 219
261 IF (FIG=22 OR FIG=23)AND C=0 THEN L$="IL FAUT UNE CLEF":GOSUB 485:GOTO 219
263 IF (FIG=24 OR FIG=25)AND A=0 THEN L$="IL FAUT LE CODE":GOSUB 485:GOTO 219
265 IF FIG=27 AND A=0 THEN L$="IL FAUT LE CODE":GOSUB 485:GOTO 219
267 IF FIG=21 AND C=1 THEN C=0:FIG=2
269 IF FIG=22 AND C=1 THEN C=0:FIG=3
271 IF FIG=23 AND C=1 THEN C=0:FIG=4
273 IF FIG=24 AND A=1 THEN A=0:FIG=3
275 IF FIG=25 AND A=1 THEN A=0:FIG=4
277 IF FIG=27 AND A=1 THEN A=0:FIG=2
279 IF FIG=26 THEN L$="SOYEZ SYMPA .... JOUEZ AVEC NOUS":GOSUB 485:GOTO 219
281 IF FIG=20 AND C=1 THEN 289
283 ON FIG GOSUB 399,415,429,443,461,513,569,593,611,633
285 IF L$="MORT" THEN CLS "WBB":CALL COLOR("0RBH"):GOTO 291
287 F=E:E=G:GOTO 219:END!!
289 GOSUB 651:CLS "BMM":CALL COLOR("0BYH")
291 LOCATE (11,6):PRINT "VOULEZ-VOUS REJOUER ? [O/N]"
292 LOCATE (12,6):PRINT "VOULEZ-VOUS REJOUER ? [O/N]"
293 LOCATE (14,6):PRINT "[ESC]=RETOUR AU MENU PRINCIPAL"
294 LOCATE (15,6):PRINT "[ESC]=RETOUR AU MENU PRINCIPAL"
295 L$=KEY$:IF L$="O" THEN 179
297 IF L$<>"N" THEN 297
299 CLS "YGM":LOCATE (14,17):PRINT "AU REVOIR":LOCATE (15,17):PRINT "AU REVOIR"
301 PAUSE 6:CLS "BCC":END
303 !
305 ! GRAND LABYRINTHE
307 !
309 DATA 212300J000,23D0002300,32:?001244,34001244:?,3?1244:?00,?3I:003300
311 DATA ?:H3004:00,48A5439800,4598003543,8449003400,8934004900,54369@2400
313 DATA 5@00369@@4,56@400369@,6587>:2500,67250087>:,6:00873:25,7650002600
315 DATA :68J:?4600,:?008J:??6,:J?6008J:?,J:;I002:00,JI<:004I00,IJ009H8J87
317 DATA IH87009H8J,I79H8J8700,7I50003I00,HI3F002I00,HF2I003F00,FG7H001G6E
319 DATA FH1G6E7H00,FE001G6E7H,GFG>002F00,G>EF004>00,EF2D004F00,ED4F002D00
321 DATA DE1C006E==,D=006E4=1C,DC6E==1C00,CDEA003D00,CAFD002A00,AC7@001C6B
323 DATA AB001C6B7@,A@1C6B7@00,@53A004500,@A45003A00,BA4;004A00,B;4A004;00
325 DATA 98008778B;,97B;008778,9;87782;00,7950002900,;91<00396B,;B00C96B1<
327 DATA ;<C96B1<00,<;E=003;00,<=F;002=00,=>1<=D2>00,=<@>001<=D,=D001<4D@>
329 DATA >=87003=1G,>G003=1G87,>7A=1G8700,7>50003>00,4300A54398
331 !
333 ! PETIT LABYRINTHE
335 !
337 DATA 212300J000,23D0002300,32:40012>>,3412>>:400,3>0012>>:4,43K5003300
339 DATA 45H3002500,54?600:47A,5A00:47A?6,56:47A?600,67B80087>5,650087>5B8
341 DATA 6887>5B800,7650002600,A56@004500,A@45006@00,@A9?009A00,@?9A009?00
343 DATA >3:==8?300,>800:==8?3,>=?300:==8,8>00C6=>69,89C6=>6900,866900C6=>
345 DATA =>I<002>00,=<K>004<00,?;6@004;00,?@4;006@00,9:38004:00,984:003800
347 DATA 7<50003<00,<7C;:=8700,<;8700C;:=,<=00C;:=87,;<A:7?B<00,;?00A:7?2<
349 DATA ;:B<00A:7?,:7@;008769,:;8769@;00,:9008769@;,7:50002:00
351 !
353 ! DESSIN DU COULOIR DE BASE
355 !
357 CLS "BYC":CALL COLOR("0WB"):A$=RPT$(CHR$(12),40)
359 LOCATE (21,1):PRINT A$
361 FOR I=1 TO 10:J=21-I:K=2*I-2:A$=RPT$(" ",K):LOCATE (I,J):CALL COLOR("1RY")
363 PRINT CHR$(21);:CALL COLOR("0RR"):PRINT A$;:CALL COLOR("1RY"):PRINT CHR$(22)
365 NEXT:CALL COLOR("0RR")
367 FOR I=11 TO 20:LOCATE (I,11):PRINT RPT$(" ",20):NEXT:CALL COLOR("1RY")
369 LOCATE (1,20):PRINT CHR$(31);CHR$(33)
371 FOR I=2 TO 5:LOCATE (I,20):PRINT CHR$(34);CHR$(35):NEXT
373 FOR I=6 TO 20 STEP 3:Y=I-5:J=INT((Y+1)*2/3):K=21-J:J=2*J-2:CALL COLOR("1CR")
375 A$=RPT$(" ",J):LOCATE (I,K):PRINT CHR$(23);:CALL COLOR("0CC"):PRINT A$;
377 CALL COLOR("1CR"):PRINT CHR$(24):LOCATE (I+1,K-1):PRINT CHR$(25);CHR$(26);
379 CALL COLOR("0CC"):PRINT A$;:CALL COLOR("1CR"):PRINT CHR$(27);CHR$(28)
381 LOCATE (I+2,K-1):PRINT CHR$(29);:CALL COLOR("0CC"):PRINT " ";A$;" ";
383 CALL COLOR("1CR"):PRINT CHR$(30):NEXT:CALL COLOR("1BY"):I=19
385 IF A=1 THEN LOCATE (I,35):PRINT CHR$(17);CHR$(18);CHR$(19) ELSE I=I+1
387 I=I-1:IF B=1 THEN LOCATE (I,35):PRINT CHR$(14);CHR$(15);CHR$(16) ELSE I=I+1
389 I=I-1:IF C=1 THEN LOCATE (I,35):PRINT CHR$(11);CHR$(12);CHR$(13)
391 RETURN
393 !
395 ! DESSIN D'UNE PORTE
397 !
399 GOSUB 357
401 CALL COLOR("0bb"):FOR I=9 TO 17:LOCATE (I,13):PRINT RPT$(" ",16):NEXT
403 CALL COLOR("1bC"):FOR I=9 TO 17:LOCATE (I,20):PRINT CHR$(34);CHR$(35)
405 NEXT:LOCATE (13,22):PRINT CHR$(37):LOCATE (14,22):PRINT CHR$(38)
407 L$="VOUS ETES DEVANT UNE PORTE":GOSUB 485:RETURN
409 !
411 ! DESSIN COULOIR A GAUCHE
413 !
415 GOSUB 357
417 CALL COLOR("0bb"):FOR I=5 TO 8:LOCATE (I,1):PRINT RPT$(" ",16):NEXT
419 FOR I=9 TO 17:LOCATE (I,13):PRINT " ":IF I=11 THEN CALL COLOR("0CC")
421 NEXT:L$="CONTINUEZ OU TOURNEZ A GAUCHE":GOSUB 485:RETURN
423 !
425 ! DESSIN COULOIR A DROITE
427 !
429 GOSUB 357
431 CALL COLOR("0bb"):FOR I=5 TO 8:LOCATE (I,25):PRINT RPT$(" ",16):NEXT
433 FOR I=9 TO 17:LOCATE (I,25):PRINT " ":IF I=11 THEN CALL COLOR("0CC")
435 NEXT:L$="CONTINUEZ OU TOURNEZ A DROITE":GOSUB 485:RETURN
437 !
439 ! DESSIN COULOIR PERPENDICULAIRE
441 !
443 GOSUB 357
445 CALL COLOR("0YY"):LOCATE (1,19):PRINT " ":LOCATE (2,19):PRINT " "
447 CALL COLOR("0bb"):FOR I=3 TO 6:LOCATE (I,1):PRINT RPT$(" ",40):NEXT
449 FOR I=7 TO 14:LOCATE (I,15):PRINT RPT$(" ",12)
451 IF I=8 THEN CALL COLOR("0CC")
453 NEXT:L$="TOURNEZ A GAUCHE OU A DROITE":GOSUB 485:RETURN
455 !
457 ! DESSIN OUBLIETTE
459 !
461 GOSUB 357
463 CALL COLOR("0RR"):FOR I=15 TO 20:LOCATE (I,11):PRINT RPT$(" ",20):NEXT
465 CALL COLOR("0bb"):FOR I=15 TO 19:LOCATE (I,15):PRINT RPT$(" ",12):NEXT
467 CALL COLOR("1BR"):LOCATE (20,14):PRINT CHR$(23);:CALL COLOR("0BB")
469 PRINT RPT$(" ",12);:CALL COLOR("1BR"):PRINT CHR$(24):PAUSE 2
471 L$="VOUS TOMBEZ DANS UNE OUBLIETTE":GOSUB 485:PAUSE 1:CALL COLOR("0BB")
473 A$=RPT$(" ",40):FOR I=1 TO 20:LOCATE (I,1):PRINT A$:NEXT
475 L$="VOUS MOURREZ LENTEMENT":GOSUB 485:PAUSE 2
477 L$="VOUS ETES MORT":CLS "WBB":GOSUB 485:L$="MORT":RETURN
479 !
481 ! BANDE TEXTE
483 !
485 TCH$="430C6788EBF35934D70F9930491D82A63491AD9DDBEB"
487 IF TCH=1 THEN TCH$="238A7BCF5F13E8BCCCFF944454814085B4CBDBD1779E":GOTO 495
489 IF TCH=3 THEN TCH$="1395B9090F633B9807E76B25FAC9ACE397819D2DAA7C":GOTO 495
491 IF TCH=5 THEN TCH$="3B43D4381BECD394F3ED2B897764C0ECB05173F7C41A":GOTO 495
493 IF TCH=7 THEN TCH$="C5099380A5BB09BA0475BCCDDBF9831F7F63E0F151CD"
495 CALL SPEECH("L,"&TCH$)
497 LOCATE (21,1):CALL COLOR("0BM"):PRINT RPT$(CHR$(12),40)
499 D=1+INT(20-LEN(L$)/2)
501 FOR I=D TO D+LEN(L$)-1:CALL COLOR("0RR")
503 PRINT " ":CALL COLOR("0CB"):LOCATE (21,I):PRINT SEG$(L$,I-D+1,1):NEXT
505 PAUSE 1:CALL SPEECH("A,"&TCH$):RETURN
507 !
509 ! DESSIN MONSTRE
511 !
513 GOSUB 357:L$="UN MONSTRE SURGIT AU BOUT DU COULOIR":GOSUB 485
515 FOR I=1 TO 15:CALL COLOR("1YR"):LOCATE (5,20):PRINT CHR$(9);CHR$(10)
517 CALL COLOR("1BR"):LOCATE (5,20):PRINT CHR$(9);CHR$(10):NEXT:PAUSE 1
519 L$="LE MONSTRE APPROCHE, TIREZ!!!":GOSUB 485
521 CALL COLOR("1RY"):LOCATE (5,20):PRINT CHR$(34);CHR$(35)
523 FOR I=1 TO 15:CALL COLOR("1YC"):LOCATE (9,19)
525 PRINT CHR$(5);CHR$(6);CHR$(7);CHR$(8):LOCATE (10,19)
527 PRINT CHR$(1);CHR$(2);CHR$(3);CHR$(4):CALL COLOR("1BC"):LOCATE (10,19)
529 PRINT CHR$(1);CHR$(2);CHR$(3);CHR$(4):LOCATE (9,19)
531 PRINT CHR$(5);CHR$(6);CHR$(7);CHR$(8)
533 IF B=0 THEN 557
535 CALL KEY1(J,K):IF J<>32 THEN 557
537 CALL EXEC(50888)
539 DATA "984F0A780B0A790009FB0A","80DA1D0142B92D208A8C056499B680A4CC265080682A"
541 DATA "1210757902A2C90840D1190148DA230049653A20590F03449561806CD21550AC8502"
543 DATA "B2F15440B6EE02882E4300C9650A20790F064493C980643D091093270152F02440F4"
545 FOR K=1 TO 10:LOCATE (21-K,20):CALL COLOR("0BC"):PRINT CHR$(1)
547 LOCATE (21-K,20):CALL COLOR("0RC"):PRINT CHR$(1):LOCATE (21-K,20)
549 CALL COLOR("0CC"):PRINT " ":NEXT
551 FOR K=9 TO 11:LOCATE (K,19):PRINT " ":NEXT
553 L$="BRAVO!!! UN MONSTRE DE MOINS":GOSUB 485:B=0
555 L$="AVANCEZ OU FAITES DEMI-TOUR":GOSUB 485:RETURN
557 NEXT:IF CH=51 THEN 537
559 L$="LE MONSTRE VOUS A DEVORE,VOUS ETES MORT "
561 CLS "WBB":GOSUB 485:L$="MORT":RETURN
563 !
565 ! DESSIN MONTEE
567 !
569 GOSUB 357:CALL COLOR("1CR"):LOCATE (2,20):PRINT CHR$(23);CHR$(24)
571 FOR I=1 TO 7:CALL COLOR("1CR"):LOCATE (2*I+1,20-I):PRINT CHR$(25);
573 IF I=1 THEN CALL COLOR("1CR"):PRINT CHR$(26);CHR$(27);:GOTO 577
575 CALL COLOR("1bC"):PRINT RPT$(CHR$(36),2*I);
577 CALL COLOR("1CR"):PRINT CHR$(28):LOCATE (2*I+2,20-I):PRINT CHR$(29);
579 CALL COLOR("0CC"):PRINT RPT$(" ",2*I);:CALL COLOR("1CR"):PRINT CHR$(30)
581 NEXT:LOCATE (17,13)
583 CALL COLOR("0bb"):PRINT RPT$(" ",16):L$="MONTEZ OU FAITES DEMI-TOUR"
585 GOSUB 485:RETURN
587 !
589 ! TROU DANS COULOIR
591 !
593 GOSUB 357
595 CALL COLOR("1BR"):FOR I=9 TO 10:LOCATE (I,17):PRINT " ":NEXT
597 LOCATE (11,17):PRINT " ";CHR$(23);:CALL COLOR("0BB"):PRINT " ";
599 CALL COLOR("1BR"):PRINT CHR$(24);" ":CALL COLOR("0bb")
601 FOR I=9 TO 10:LOCATE (I,19):PRINT " ":NEXT
603 L$="VOUS POUVEZ FAIRE DEMI-TOUR":GOSUB 485:RETURN
605 !
607 ! DESSIN DESCENTE
609 !
611 GOSUB 357:CALL COLOR("0RR")
613 FOR I=7 TO 14:LOCATE (I,26-I):PRINT RPT$(" ",2*I-10):NEXT
615 FOR I=15 TO 17:LOCATE (I,11):PRINT RPT$(" ",20):NEXT:CALL COLOR("1RY")
617 FOR I=6 TO 12:LOCATE (I,20):PRINT CHR$(34);CHR$(35):NEXT
619 J=21:FOR I=1 TO 6:J=J-1:IF I>3 THEN J=J-1
621 LOCATE (I+12,J):CALL COLOR("1CR"):PRINT CHR$(23);:CALL COLOR("1bC")
623 PRINT RPT$(CHR$(20),40-2*J);:CALL COLOR("1CR"):PRINT CHR$(24):NEXT
625 L$="DESCENDEZ OU FAITES DEMI-TOUR":GOSUB 485:RETURN
627 !
629 ! PORTE CODEE
631 !
633 GOSUB 357:CALL COLOR("0bb")
635 FOR I=9 TO 17:LOCATE (I,13):PRINT RPT$(" ",16):NEXT:CALL COLOR("1bC")
637 FOR I=9 TO 17:LOCATE (I,20):PRINT CHR$(34);CHR$(35):NEXT
639 CALL COLOR("0Mb"):FOR I=12 TO 14:LOCATE (I,19):PRINT CHR$(1)
641 LOCATE (I,22):PRINT CHR$(1):NEXT
643 L$="VOUS ETES DEVANT UNE PORTE CODEE":GOSUB 485:RETURN
645 !
647 ! SORTIE
649 !
651 GOSUB 357:CALL COLOR("0CC")
653 FOR I=1 TO 6:LOCATE (I,1):PRINT RPT$(" ",40):NEXT
655 FOR I=7 TO 14:LOCATE (I,15):PRINT RPT$(" ",12):NEXT
657 L$="VOUS AVEZ GAGNE, BRAVO !!!":GOSUB 485:L$="VIVE LA LIBERTE!":GOSUB 485
659 CLS "bRR":CALL COLOR("0bRLHF")
661 LOCATE (11,16):PRINT "GGAAGGNNEE":LOCATE (12,16):PRINT "GGAAGGNNEE"
663 PAUSE 4:RETURN
665 !
667 ! SONORISATION
669 !
671 FOR I=1 TO LEN(L$)STEP 2
673 E=ASC(SEG$(L$,I,1))-48:IF E>9 THEN E=E-7
675 F=ASC(SEG$(L$,I+1,1))-48:IF F>9 THEN F=F-7
677 CALL POKE(K,16*E+F):K=K+1:NEXT:RETURN
679 !
681 ! CIRCUIT DEMONSTRATION
683 !
685 NO=NO+1:I=128:IF NO=4 OR NO=8 THEN I=130:RETURN
687 IF NO=2 OR NO=7 OR NO=12 OR NO=20 OR NO=21 THEN I=131:RETURN
689 IF NO=3 OR NO=9 OR NO=11 OR NO=14 OR NO=16 OR NO=18 THEN I=129:RETURN
691 RETURN
Ce listing est uniquement proposé pour un usage privé.
Sans accord écrit préalable, vous n'êtes pas autorisé à le distribuer, le transmettre ou le rediffuser.