1 CALL INIT
11 ! HEBDOGICIEL 146 a 149
21 ! MONKEY KONG
31 ! FRYSON ARNAUD
41 ! MAI 1986
51 !
61 CLS "RBB":GOSUB 1541
71 DIM L$(23)
81 GOSUB 1371
91 FOR I=1 TO 7:HS$(I)="EXELa"&CHR$(I+48):HS(I)=70-(I*10):NEXT I
101 !
111 ! CARACTERES SPECIAUX
121 !
131 CALL CHAR(90,"003E32240812263E")
141 CALL CHAR(65,"00186C467E464646")
151 CALL CHAR(66,"00382C2C3C26263E"):CALL CHAR(67,"001E32303030323E")
161 CALL CHAR(68,"003824262626263E"):CALL CHAR(69,"003E26203820263E")
171 CALL CHAR(70,"003E262038303038"):CALL CHAR(71,"001E32303636323C")
181 CALL CHAR(72,"002622263E262626"):CALL CHAR(73,"001E0C0808080C1E")
191 CALL CHAR(74,"001E060434342438"):CALL CHAR(75,"00242C382C242626")
201 CALL CHAR(76,"002020202030383E"):CALL CHAR(77,"00446C544444646C")
211 CALL CHAR(78,"002436362E262622"):CALL CHAR(79,"001C26222222261C")
221 CALL CHAR(80,"003C2E262C382020"):CALL CHAR(81,"001C2E26222A241A")
231 CALL CHAR(82,"003C2E263C282426"):CALL CHAR(83,"001E26201C22323C")
241 CALL CHAR(84,"003E1C0808080808"):CALL CHAR(85,"00222232323A3A1C")
251 CALL CHAR(86,"003A323232141418"):CALL CHAR(87,"0032322A2A3E3222")
261 CALL CHAR(88,"003A32140814323A"):CALL CHAR(89,"0026261408080C0C")
271 CALL CHAR(48,"003C76624242466E3C"):CALL CHAR(49,"000C3C34040404061E")
281 CALL CHAR(50,"001C3602060C18323E")
291 CALL CHAR(51,"001C3602040232361C"):CALL CHAR(52,"000C1C3C64747E0604")
301 CALL CHAR(53,"003E32203C0602361C"):CALL CHAR(54,"001E36203C3622361C")
311 CALL CHAR(55,"003E2602040C08080C"):CALL CHAR(56,"001C26321C3622361C")
321 CALL CHAR(57,"001C26321E0202261C"):CALL CHAR(0,"003C76624242466E3C")
331 CALL CHAR(97,"00000000000000000000"):CALL CHAR(98,"00000000000000000101")
341 CALL CHAR(99,"00000F3F63C1CC683032"):CALL CHAR(100,"0000F0FCC68333160C4C")
351 CALL CHAR(101,"00000000000000808080"):CALL CHAR(102,"0307070F0F1F1F1E1F1F")
361 CALL CHAR(103,"000F90C0F0FFFFFF7F7F"):CALL CHAR(104,"00F009090FFFFFFFFEFE")
371 CALL CHAR(105,"C0E0E0F0F0F8F878F8F8"):CALL CHAR(106,"0F0F07070301070F1F1F")
381 CALL CHAR(107,"BFCFF7F9FFF9FFF9FFFF"):CALL CHAR(108,"FDF3EF9FFF9FFF9FFFFF")
391 CALL CHAR(109,"F0F0E0E0C080E0F0F8F8"):CALL CHAR(110,"3F3F3F1F1F0F0F0F7FFF")
401 CALL CHAR(111,"E0C0C0C0C08080"):CALL CHAR(112,"07030303030101")
411 CALL CHAR(113,"FCFCFCF8F8F0F0F0FEFF")
421 CALL CHAR(114,"003C3E3C3C3C183C2424"):CALL CHAR(115,"3434243C18181818181C")
431 CALL CHAR(117,"3434243CFCFC06060303"):CALL CHAR(35,"0000003C7EF3E7CF7E3C")
441 CALL CHAR(43,"00FF412214081422FF"):CALL CHAR(91,"00003C7ECFE7F37E3C")
451 CALL CHAR(38,"C3C3CFF3C3C3C3F3CFC3"):CALL CHAR(122,"00000000000000000000")
461 CALL CHAR(15,"001F2F6F6E6D060F0909"):CALL CHAR(16,"0D0D0D09060606060607")
471 CALL CHAR(118,"BD3C3C7E6666666666E7"):CALL CHAR(120,"00183C3C3C3C187EBDBD")
481 CALL CHAR(40,"003C7C3C3C3C183C2424"):CALL CHAR(41,"2C2C243C181818181838")
491 CALL CHAR(42,"2C2C243C3F3F6060C0C0"):CALL CHAR(121,"3C3C3C7E6667C3C3C3C3")
501 CALL CHAR(39,"FFFFFFFFFFFFFFFFFFFF"):CALL CHAR(59,"00C381FF81C3FF")
511 CALL CHAR(60,"1C362B2F371B0F070301"):CALL CHAR(62,"387CFCFCFCF8F0E0C080")
521 GOSUB 1821
531 !
541 ! DECORS
551 !
561 NRJ=99:LI=0
571 FOR I=1 TO 5:CALL COLOR("1bB"):LOCATE (I,1):PRINT RPT$(CHR$(12),40):NEXT I
581 CALL COLOR("1CB"):LOCATE (8,2):PRINT RPT$("+",32):LOCATE (9,33)
591 PRINT RPT$("+",6)
601 FOR I=1 TO 3:EM=I*4+8:LOCATE (EM,2):PRINT RPT$("+",38):NEXT I
611 FOR I=1 TO 4:CALL COLOR("1WB"):LOCATE (I+7,29):PRINT "&":LOCATE (I+11,5)
621 PRINT "&":LOCATE (I+15,35):PRINT "&":NEXT I
631 CALL COLOR("1YB"):LOCATE (5,35):PRINT "bcde":LOCATE (6,35):PRINT "fghi"
641 LOCATE (7,35):PRINT "jklm":LOCATE (8,35):PRINT "nopq"
651 CALL COLOR("1GB"):LOCATE (6,4):PRINT CHR$(15):LOCATE (7,4):PRINT CHR$(16)
661 CALL COLOR("1Rb"):LOCATE (2,2):PRINT USING"ENERGYa##%";NRJ
671 CALL COLOR("1Mb"):LOCATE (2,17):PRINT "LEVELaa";NIV$
681 CALL COLOR("1Gb"):LOCATE (2,30):PRINT "LIVESa4"
691 CALL COLOR("1Yb"):LOCATE (4,10):PRINT USING"HIGHaSCOREa######";HSC
701 CALL COLOR("1bY"):LOCATE (22,5):PRINT USING"SCOREa######";SC
711 CALL COLOR("1YB"):LOCATE (17,18):PRINT RPT$(";",16):LOCATE (13,25)
721 CALL COLOR("1MB"):LOCATE (Y,X):PRINT "u":LOCATE (Y-1,X):PRINT "r"
731 CALL COLOR("1GbF"):LOCATE (22,30):PRINT "aPRETa?a":A$=KEY$
741 CALL COLOR("1BB"):LOCATE (22,30):PRINT "aaaaaaaa"
751 !
761 ! PROGRAMME PRINCIPAL
771 !
781 FOR DF=1 TO CVB
791 GOSUB 1041
801 FOR LF=1 TO 2
811 CALL KEY1(CC,TT):IF TT=0 THEN GOSUB 1161:GOTO 991
821 CALL COLOR("1Rb"):NRJ=NRJ-1:LOCATE (2,9):PRINT USING"##%";NRJ
831 IF NRJ=0 THEN 2611
841 IF CC=128 AND SEG$(L$(Y-2),X,1)<>"z" THEN Y=Y-2:GOSUB 1771:GOTO 901
851 IF CC=129 AND SEG$(L$(Y),X+2,1)<>"z" THEN X=X+2:GOSUB 1751:GOTO 901
861 IF CC=130 AND SEG$(L$(Y+2),X,1)<>"z" THEN Y=Y+2:GOSUB 1771:GOTO 901
871 IF CC=131 AND SEG$(L$(Y),X-2,1)<>"z" THEN X=X-2:GOSUB 1801:GOTO 901
881 IF CC=32 THEN GOSUB 1581:GOTO 971
891 GOTO 971
901 CALL POKE(258,180,135)
911 CALL COLOR("1MB"):LOCATE (DY,DX):PRINT C1$:PAUSE .00001:LOCATE (DY,DX)
921 CALL COLOR("1WB"):PRINT SEG$(L$(DY),DX,1):LOCATE (DY-1,DX)
931 PRINT SEG$(L$(DY-1),DX,1):CALL COLOR("1MB"):LOCATE (Y,X):PRINT C3$
941 LOCATE (Y-1,X):PRINT C2$:DX=X:DY=Y
951 IF X=5 AND Y=7 THEN NRJ=99:GOSUB 2371
961 CALL POKE(259,45)
971 GOSUB 1161
981 CALL COLOR("1RB"):LOCATE (CY,CX):PRINT "<>"
991 NEXT LF
1001 NEXT DF
1011 GOSUB 2481:GOTO 781
1021 STOP
1031 !
1041 ! DEPLACEMENT TONNEAUX
1051 !
1061 CALL COLOR("1BB")
1071 FOR I=1 TO 3:LOCATE (BY(I),BX(I)):PRINT "a"
1081 BX(I)=BX(I)+D(I)
1091 IF CA=35 THEN CA=91 ELSE CA=35
1101 IF BX(I)=2 AND BY(I)=11 THEN BY(I)=15:D(I)=2
1111 IF BX(I)=38 AND BY(I)=15 THEN BY(I)=19:D(I)=-2
1121 IF BX(I)=2 AND BY(I)=19 THEN BY(I)=11:BX(I)=36
1131 CALL COLOR("1GB"):LOCATE (BY(I),BX(I)):PRINT CHR$(CA)
1141 NEXT I:RETURN
1151 !
1161 ! FAUTE ?
1171 !
1181 FOR I=1 TO 3:ZR=BX(I)+D(I)/2:IF BY(I)=Y AND ZR=X THEN GOSUB 1211
1191 NEXT I:RETURN
1201 !
1211 ! FAUTE
1221 !
1231 LI=LI+1:CALL COLOR("1Gb"):LOCATE (2,36):PRINT CHR$(52-LI)
1241 CALL COLOR("1MBF"):LOCATE (Y-1,X):PRINT C2$:LOCATE (Y,X):PRINT C3$
1251 DATA 159,.5,159,.5,159,.1,159,.5,133,.25,141,.1,141,.5,159,.4
1261 DATA 159,.1,159,.75
1271 RESTORE 1251:FOR I=1 TO 10:READ AZ,AQ:CALL POKE(258,AZ,135):PAUSE AQ
1281 CALL POKE(259,45):NEXT I
1291 CALL COLOR("1WB"):LOCATE (Y,X):PRINT SEG$(L$(Y),X,1):LOCATE (Y-1,X)
1301 PRINT SEG$(L$(Y-1),X,1)
1311 IF LI>3 THEN GOSUB 2611
1321 X,DX=5:Y,DY=19:NRJ=99
1331 RETURN
1341 !
1351 ! DEF. DES DEPLACEMENTS
1361 !
1371 FOR I=1 TO 6:L$(I)="zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz":NEXT I
1381 L$(7)="zzzzaaaaaaaaaaaaaaaaaaaaaaaaazzzzzzzzzzz"
1391 L$(8)="zzzzzzzzzzzzzzzzzzzzzzzzzzzz&zzzzzzzzzzz"
1401 L$(9)="zzzzzzzzzzzzzzzzzzzzzzzzzzzz&zzzzzzzzzzz"
1411 L$(10)="zzzzzzzzzzzzzzzzzzzzzzzzzzzz&zzzzzzzzzzz"
1421 L$(11)="zzzzaaaaaaaaaaaaaaaaaaaaaaaa&aaaaaazzzzz"
1431 L$(12)="zzzz&zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz"
1441 L$(13)="zzzz&zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz"
1451 L$(14)="zzzz&zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz"
1461 L$(15)="zzzz&aaaaaaaaaaaaaaaaaaaaaaaaaaaaaazzzzz"
1471 L$(16)="zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz&zzzzz"
1481 L$(17)="zzzzzzzzzzzzzzzzzzz!z!z!z!z!z!z!z!&zzzzz"
1491 L$(18)="zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz&zzzzz"
1501 L$(19)="zzzzaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa&zzzzz"
1511 FOR I=20 TO 23:L$(I)="zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz":NEXT I
1521 RETURN
1531 !VARIABLES
1541 BY(1)=11:BY(2)=15:BY(3)=19:BX(1)=20:BX(2)=6:BX(3)=40:D(1)=-2:D(2)=2:D(3)=-2
1551 X,DX=5:Y,DY=19:CX=INTRND(11)+5:CY=7
1561 RETURN
1571 !
1581 !SAUT
1591 !
1601 IF SEG$(L$(Y-2),X+1,1)="!"OR Y=7 THEN RETURN
1611 CALL COLOR("1WB"):LOCATE (Y,X):PRINT SEG$(L$(Y),X,1):Y=Y-1:LOCATE (Y,X)
1621 CALL POKE(258,60,132)
1631 CALL COLOR("1MB"):PRINT "y"::LOCATE (Y-1,X):PRINT "x":GOSUB 1041
1641 CALL COLOR("1WB"):LOCATE (Y-1,X):PRINT SEG$(L$(Y-1),X,1):LOCATE (Y,X)
1651 CALL COLOR("1MB"):PRINT "x":LOCATE (Y+1,X):PRINT "y":GOSUB 1161
1661 CALL POKE(258,75,132)
1671 Y=Y+1:FOR I=1 TO 3:IF X=BX(I)-(D(I)/2)AND Y=BY(I)THEN SC=SC+100:GOSUB 1701
1681 NEXT I:CALL POKE(259,45):RETURN
1691 !
1701 ! AFF.SCORE
1711 !
1721 CALL COLOR("1bY"):LOCATE (22,11):PRINT USING"######";SC
1731 IF SC>=1.E+05 THEN SC=0
1741 RETURN
1751 ! DROITE
1761 C1$="u":C2$="r":C3$="s":RETURN
1771 ! IMMOBILE
1781 C1$="v":C2$="x":C3$="v":RETURN
1791 ! GAUCHE
1801 C1$="*":C2$="(":C3$=")":RETURN
1811 !
1821 ! TITRE
1831 !
1841 CALL COLOR("1GB"):LOCATE (4,1):PRINT RPT$(CHR$(30),40)
1851 LOCATE (5,1):PRINT RPT$(CHR$(29),40)
1861 CALL COLOR("1YBHL"):LOCATE (4,9):PRINT "MMOONNKKEEYY KKOONNGG"
1871 LOCATE (5,9):PRINT "MMOONNKKEEYY KKOONNGG"
1881 CALL COLOR("1RB"):LOCATE (14,2):PRINT RPT$("+",38)
1891 PAUSE 2:FOR I=2 TO 18
1901 CALL COLOR("1CB"):LOCATE (10,I):PRINT "bcde":LOCATE (11,I)
1911 PRINT "fghi":LOCATE (12,I):PRINT "jklm":LOCATE (13,I):PRINT "nopq"
1921 FOR MB=10 TO 13:LOCATE (MB,I-1):PRINT "a":NEXT MB:NEXT I
1931 !
1941 ! REGLES
1951 !
1961 PAUSE 2:A$="DESIREZaVOUSaCONNAITREaLESaREGLESa?":RT=LEN(A$):SB=0
1971 FOR I=1 TO RT:SB=SB+1:CALL COLOR("1WB"):FOR VM=15 TO 20:LOCATE (VM,I+3)
1981 PRINT SEG$(A$,SB,1):LOCATE (VM,I+3):PRINT "a":NEXT VM:CALL POKE(258,35,132)
1991 CALL POKE(258,2*I+35,135):PAUSE .001:CALL POKE(259,45)
2001 LOCATE (20,I+3):PRINT SEG$(A$,SB,1):NEXT I
2011 CALL KEY1(RS,RU):IF RS<>79 AND RS<>78 THEN 2011
2021 IF RS<>79 THEN 2291
2031 CALL COLOR("1bb"):FOR I=7 TO 20:LOCATE (I,1):PRINT RPT$("a",40):NEXT I
2041 CALL COLOR("1Mb")
2051 CALL AF("VOTREaTACHEaCONSISTEaAaDELIVRERaVOTRE",10)
2061 CALL AF("FIANCEEaENLEVEEaPARaMONKEYaKONG",11)
2071 CALL AF("CELUI-CIaVOUSaJETTEaDESaTONNEAUX",12)
2081 CALL AF("AaVOUSaDEaLESaEVITERaENaAPPUYANT",13)
2091 CALL AF("SURaFEUaOUaESPACEaaVOUSaGAGNEZaALORS",14)
2101 CALL AF("100aPOINTSaaLAaSECONDEaDIFFICULTE",15)
2111 CALL AF("SERAaLAaSUIVANTE",16)
2121 PET$=KEY$
2131 CALL COLOR("1bb"):FOR I=7 TO 20:LOCATE (I,1):PRINT RPT$("a",40):NEXT I
2141 CALL COLOR("1Mb"):CALL AF("DUaHAUTaDEaLaECHAFAUDAGEaVOTRE",10)
2151 CALL AF("FIANCEEaVOUSaJETTEaUNaCOEUR",11)
2161 CALL AF("SIaCELUI-CIaPARVIENTaAaTOUCHER",12)
2171 CALL AF("LEaSOLaALORSaVOUSaPERDEZaUNEaVIE",13)
2181 CALL AF("DONCaILaFAUTaFAIREaLEaPLUSaVITE",14)
2191 CALL AF("POSSIBLEaPOURaREJOINDREaVOTREaFIANCEE",15)
2201 PET$=KEY$
2211 CALL COLOR("1bb"):FOR I=7 TO 20:LOCATE (I,1):PRINT RPT$("a",40):NEXT I
2221 CALL COLOR("1Mb"):CALL AF("ATTENTIONaLaENERGIEaBAISSEaET",10)
2231 CALL AF("SIaELLEaT0MBEaAaZEROaLAaPARTIEaSE",11)
2241 CALL AF("TERMINEaaENFINaSIaVOUSaARRIVEZaA",12)
2251 CALL AF("REJOINDREaVOTREaFIANCEEaVOUSaGAGNEREZ",13)
2261 CALL AF("500aPOINTS",14)
2271 CALL COLOR("1Wb"):CALL AF("BONNEaCHANCEa...",16)
2281 PET$=KEY$
2291 CLS "RBB"
2301 CALL COLOR("1CB"):LOCATE (10,5):PRINT "AaQUELaNIVEAUaVOULEZ-VOUSaJOUERa?"
2311 CALL COLOR("1WB"):CALL AF("1a-a2a-a3",12)
2321 CALL KEY1(FG,KY):IF FG<>49 AND FG<>50 AND FG<>51 THEN 2321
2331 CLS "CBB":NIV$=CHR$(FG):CVB=INT(20/VAL(NIV$))
2341 RETURN
2351 !
2361 ! PARCOURS ACHEVE
2371 !
2381 CALL POKE(259,45)
2391 FOR PK=1 TO 50:SC=SC+10:GOSUB 1721:CALL SPEECH("L,0D7C91B2BAB602FC"):NEXT
2401 CALL COLOR("1MB")
2411 LOCATE (Y,X):PRINT "a":LOCATE (Y-1,X):PRINT "a":X,DX=5:Y,DY=19
2421 IF CY=8 OR CY=12 OR CY=16 OR CY=20 THEN CU$="+" ELSE CU$="a"
2431 CALL COLOR("1CB"):LOCATE (CY,CX):PRINT CU$;CU$:CY=7:CX=INTRND(11)+5
2441 CALL COLOR("1MB"):LOCATE (Y,X):PRINT "u":LOCATE (Y-1,X):PRINT "r":RETURN
2451 !
2461 ! DEPLACEMENT COEUR
2471 !
2481 IF CY=8 OR CY=12 OR CY=16 THEN CU$="+" ELSE CU$="a"
2491 CALL COLOR("1CB"):LOCATE (CY,CX):PRINT CU$;CU$:CY=CY+1:DM=INTRND(2)
2501 ON DM GOTO 2511,2521
2511 IF CX=6 THEN 2531 ELSE CX=CX-1:GOTO 2531
2521 IF CX=15 THEN 2531 ELSE CX=CX+1:GOTO 2531
2531 CALL COLOR("1RB"):LOCATE (CY,CX):PRINT "<>"
2541 IF CY=20 THEN GOSUB 1211:GOSUB 2561 ELSE 2551
2551 RETURN
2561 NRJ=99:CALL COLOR("1CB"):LOCATE (CY,CX):PRINT "++":CX=INTRND(11)+5:CY=7
2571 RETURN
2581 !
2591 ! CLASSEMENT
2601 !
2611 CALL POKE(259,45):CLS "CBB":IF SC>HS(7)THEN GOSUB 2781
2621 FOR T=1 TO 7:IF SC>HS(T)THEN 2641
2631 NEXT T
2641 FOR I=1 TO 7:IF HS$(I)=NAM$ THEN IF SC>HS(I)THEN HS(I)=SC:GOTO 2681
2651 NEXT I
2661 FOR L=7 TO T STEP -1:HS$(L+1)=HS$(L):HS(L+1)=HS(L):NEXT L:HS$(T)=NAM$
2671 HS(T)=SC
2681 CALL COLOR("1Wb"):LOCATE (6,5):PRINT "CLASSEMENTaDESaMEILLEURSaSCORES"
2691 CALL COLOR("1WRF"):LOCATE (10,10):NPTS=14-LEN(HS$(1))
2701 PRINT HS$(1);RPT$(".",NPTS);:PRINT USING"######";HS(1)
2711 CALL COLOR("1GB"):FOR Q=2 TO 7:NPT=14-LEN(HS$(Q)):LOCATE (Q+10,10)
2721 PRINT HS$(Q);RPT$(".",NPT);:PRINT USING"######";HS(Q):NEXT Q
2731 HSC=HS(1):PAUSE 10:CLS:GOSUB 1821:GOSUB 1541:SC=0:GOTO 541
2741 RETURN
2751 !
2761 !INSCRIPTION DU NOM
2771 !
2781 ER$="aaaaaaaaaaaaaaaaABCDEFGHIJKLMNOPQRSTUVWXYZaaaaaaaaaaaaaa":NX=15
2791 CALL COLOR("0MB"):LOCATE (12,1):PRINT RPT$("*",40)
2801 NAM$="":OT=0
2811 CALL COLOR("1bR"):LOCATE (16,8):PRINT "NAME"
2821 CALL COLOR("1Rb"):LOCATE (5,5):PRINT "VOTREaSCOREaESTaUNaDESa7aMEILLEURS"
2831 CALL COLOR("1GB")
2841 LOCATE (19,1):PRINT ".......FLECHES.POUR.SE.DIRIGER.........."
2851 PRINT ".............F.POUR.FINIR................"
2861 PRINT ".....ESPACE.POUR.VALIDER.UNE.LETTRE....."
2871 CALL COLOR("1R"):LOCATE (7,5):PRINT "INSCRIVEZaVOTREaNOMaS.V.P"
2881 CALL COLOR("0YB"):LOCATE (13,20):PRINT "^"
2891 CALL COLOR("1BW"):LOCATE (12,15):PRINT SEG$(ER$,NX,10)
2901 CALL KEY1(RO,KJ):IF KJ=0 THEN 2901
2911 IF RO=129 AND NX<37 THEN NX=NX+1
2921 IF RO=131 AND NX>12 THEN NX=NX-1
2931 IF RO=70 THEN CLS:RETURN
2941 IF RO=32 THEN 2971
2951 CALL COLOR("1BW"):LOCATE (12,15):PRINT SEG$(ER$,NX,10)
2961 PAUSE .1:GOTO 2901
2971 CALL COLOR("1BC"):LOCATE (16,OT+13):PRINT SEG$(ER$,NX+5,1):OT=OT+1
2981 IF OT=10 THEN CLS:RETURN
2991 NAM$=NAM$&SEG$(ER$,NX+5,1)
3001 PAUSE .1:GOTO 2901
3011 RETURN
3021 SUB INIT
3031 CALL POKE(50850,162,5,45,162,136,45,10):CALL EXEC(50850)
3041 CALL POKE(50688,165,8,6,10):CALL POKE(49156,198,0):SUBEND
3051 SUB AF(GH$,XS)
3061 PY=(40-LEN(GH$))/2-1
3071 FOR HJ=1 TO LEN(GH$):LOCATE (XS,PY+HJ):PRINT SEG$(GH$,HJ,1):NEXT HJ
3081 SUBEND
Ce listing est uniquement proposé pour un usage privé.
Sans accord écrit préalable, vous n'êtes pas autorisé à le distribuer, le transmettre ou le rediffuser.