Note: L'EXL100 ne pouvant charger la totalité du programme en mémoire, SATURNE 3 est scindé en deux programmes «SATURNE0.BAS» et «SATURNE1.BAS». Le listing a été adapté pour une utilisation sur disquette. Exécutez le premier programme, la seconde partie se lancera automatiquement.
1ER LISTING:
8 CALL CHAR(1,"00000000181800000000")
9 CALL CHAR(2,"0000183C343C18000000")
10 CALL CHAR(3,"187E7EFFDFDFDF6E7E18")
11 CALL CHAR(4,"FFFFFBFBE7DFDFFFFFFF")
12 CALL CHAR(5,"FCFEFE9E9E9F9FDFFFFE")
13 CALL CHAR(6,"00000080C0E0F0F8F8FC")
14 CALL CHAR(7,"00007CFBFBE3C78FDFFF")
15 CALL CHAR(8,"0000000103070F1F1F3F")
16 CALL CHAR(9,"3F7F7FF7E3E7F1F9F97F")
17 CALL CHAR(10,"7F3F3F1F0F0703000000")
18 CALL CHAR(11,"FFEFEFCF8FC7FFFF7E00")
19 CALL CHAR(12,"8EBC7CF8F8F0E0800000")
20 CALL CHAR(13,"C0E0E0F0F0F0E0E0C0C0")
21 CALL CHAR(14,"000000000000000080C0")
22 CALL CHAR(15,"0000000000007EEFCDFF")
23 CALL CHAR(16,"00000000000000010307")
24 CALL CHAR(17,"0F0F1F1F1F0F0F070703")
25 CALL CHAR(18,"01000000000000000000")
26 CALL CHAR(19,"FF7E0000000000000000")
27 CALL CHAR(20,"80000000000000000000")
28 CALL CHAR(21,"010307070F1F3F3F7FFF")
29 CALL CHAR(22,"80C0E0E0F0F8FCFCFEFF")
30 CALL CHAR(23,"00FF00000000FFFF0000")
31 CALL CHAR(24,"003C7EFFFFFFFF7E3C00")
32 CALL CHAR(25,"FF017D455D5D5D417F00")
33 CALL CHAR(26,"18183C6666667E7E7E7E")
34 CALL CHAR(27,"BDDBBDDBBDDBBDDB6600")
35 CALL CHAR(28,"00C0C0E0F2FAFEFEFE02")
36 CALL CHAR(29,"000303070F5F7F7F7F40")
37 CALL CHAR(30,"1C1C1C22142214080000")
38 CALL CHAR(31,"181818183C3C5AFFFF00")
39 CALL CHAR(43,"00C0E0D8FFFFD8E0C000")
40 CALL CHAR(33,"0003071BFFFF1B070300")
41 CALL CHAR(34,"00FFFF5A3C3C18181818")
42 CALL CHAR(35,"00183C3C3C1818180000")
43 CALL CHAR(36,"0000001C7E7E1C000000")
44 CALL CHAR(37,"000000387F7F38000000")
45 CALL CHAR(38,"00001818183C3C3C1800")
46 CALL CHAR(39,"000000070F3F7F3FC7F8")
47 CALL CHAR(40,"0000E0F0FCFEFEFFFFF8")
48 CALL CHAR(41,"7F8FF1FEFEFCF0E00000")
49 CALL CHAR(42,"FFFFFF7F7F3F0F070000")
50 !
51 CLS "CBB"
52 FOR I=1 TO 100
53 CALL COLOR("1WB")
54 RANDOMIZE:X=INTRND(22)
55 RANDOMIZE:Y=INTRND(40)
56 LOCATE (X,Y):PRINT CHR$(1)
57 NEXT I
58 FOR I=1 TO 20
59 RANDOMIZE:X=INTRND(22)
60 RANDOMIZE:Y=INTRND(40)
61 LOCATE (X,Y):PRINT CHR$(2)
62 NEXT I
63 CALL COLOR("0RHLF")
64 LOCATE (4,11):PRINT "SSAATTUURRNNEE 33"
65 LOCATE (5,11):PRINT "SSAATTUURRNNEE 33"
66 CALL COLOR("0CB")
67 LOCATE (14,2):PRINT "Voulez-vous des explications ? [O/N]"
68 K$=KEY$
69 IF K$="O" THEN 71
70 IF K$="N" THEN 135
71 CLS
72 CALL AF("LE LOGICIEL SATURNE 3",5)
73 CALL AF("A ETE ECRIT EN DEUX PARTIES.",7)
74 CALL AF("POUR JOUER,VOUS POUVEZ VOUS SERVIR",9)
75 CALL AF("DU CLAVIER OU DE LA MANETTE ORANGE.",11)
76 GOSUB 136
77 CALL AF("CE JEU SE COMPOSE DE 3 TABLEAUX",3)
78 CALL AF("ET POSSEDE 4 NIVEAUX DE DIFFICULTE.",5)
79 CALL AF("VOUS ETES PILOTE DE VAISSEAU SPATIAL,",7)
80 CALL AF("VOUS AVEZ UNE MISSION A ACCOMPLIR",9)
81 CALL AF("EN RESPECTANT LES LIMITES ",11)
82 CALL AF("DE VOTRE CARBURANT EMPORTE.",13)
83 CALL AF("CARBURANT AU DEPART:5000 KG",15)
84 GOSUB 136
85 CALL AF("PREMIER TABLEAU",1)
86 CALL AF("MISE EN ORBITE AUTOUR DE SATURNE",3)
87 CALL AF("DEPLACEMENTS:",5)
88 CALL AF("ORIENTATION:CURSEUR/MANCHE MANETTE.",7)
89 CALL AF("PROPULSION:BARRE ESPACE/TIR MANETTE.",9)
90 CALL AF("VOUS DEVEZ LUTTER CONTRE",11)
91 CALL AF("L'ATTRACTION DE SATURNE",13)
92 CALL AF("ET L'INERTIE DUE A L'ESPACE.",15)
93 CALL AF("SI VOTRE VITESSE DE MISE EN ORBITE",17)
94 CALL AF("EST TROP FORTE,VOUS SEREZ REPOUSSE",19)
95 CALL AF("LOIN DE SATURNE.",21)
96 GOSUB 136
97 CALL AF("SI VOUS SORTEZ DE L'ECRAN",3)
98 CALL AF(" VOUS REAPARAITREZ A L'AUTRE EXTREMITE.",5)
99 CALL AF("LE CARBURANT RESTANT EST",7)
100 CALL AF("AFFICHE EN BAS ET A GAUCHE DE L'ECRAN.",9)
101 GOSUB 136
102 CALL AF("DEUXIEME TABLEAU",1)
103 CALL AF("TRAVERSEE DES ANNEAUX DE SATURNE",3)
104 CALL AF("VOUS VOUS TROUVEZ ENTRE 2 COUCHES",9)
105 CALL AF("DE METEORITES.",11)
106 CALL AF("VOUS POUVEZ LIRE VOTRE CARBURANT",5)
107 CALL AF("SUR LE TABLEAU DE BORD.",7)
108 CALL AF("DEVANT,DES METEORITES ISOLEES",13)
109 CALL AF("APPARAISSENT.POUR LES DEVIER DE",15)
110 CALL AF("VOTRE ROUTE,VOUS DEVEZ ACTIONNER",17)
111 CALL AF("LES RAYONS REPULSEURS.",19)
112 GOSUB 136
113 CALL AF("COMMANDES:CURSEURS -> <- /MANETTE.",7)
114 CALL AF("SI VOUS ETES TOUCHE EN FIN",9)
115 CALL AF("DE TABLEAU,VOUS AVEZ UNE PETITE ",11)
116 CALL AF("CHANCE DE SURVIVRE AU CHOC.",13)
117 GOSUB 136
118 CALL AF("TROISIEME TABLEAU",1)
119 CALL AF("ATTERRISSAGE SUR SATURNE",3)
120 CALL AF("LA SURFACE DE LA PLANETE EST ",5)
121 CALL AF("MATERIALISEE EN BAS DE L'ECRAN",7)
122 CALL AF("(TERRAIN D'ATTERRISSAGE AU MILIEU).",9)
123 CALL AF("SUR L'ECRAN 3 SYMBOLES:",11)
124 CALL AF("VZ:VITESSE VERTICALE.ELLE DOIT ETRE",13)
125 CALL AF("INFERIEURE A 3 POUR TOUCHER LE SOL.",15)
126 CALL AF("EC:ECART LATERAL.IL DOIT ETRE",17)
127 CALL AF("NUL POUR L'ATTERRISSAGE.",19)
128 GOSUB 136
129 CALL AF("CA:CARBURANT RESTANT.",1)
130 CALL AF("DEPLACEMENTS:<- -> /MANCHE MANETTE.",3)
131 CALL AF("PROPULSION:BARRE ESPACE / TIR MANETTE.",5)
132 CALL AF("VOUS DEVEZ LUTTER CONTRE LA FORCE",7)
133 CALL AF("D'ATTRACTION ET LA FORCE D'INERTIE.",9)
134 CALL AF("BONNE CHANCE",15)
135 CALL DOS("LOADRUN A:SATURNE1.BAS")
136 CALL COLOR("0YB"):LOCATE (22,8):PRINT "appuyez sur une touche"
137 K$=KEY$
138 CLS
139 RETURN
140 SUB AF(A$,X)
141 CALL COLOR("0CB"):LOCATE (X,(40-LEN(A$))/2)
142 PRINT A$
143 SUBEND
2EME LISTING:
1 !
2 EX1$="0BA02163031B18008D1E139840073A108100F0901E81080480478F084420020570"
3 EX2$="CEBD02110840704E118840043CE0010F78C00316B080052C20010948800214A"
4 EX3$="0000528":EX$=EX1$&EX2$&EX3$
5 B1$="0E683FC7031EF040043CE0010F78C00216B040042C60010F5840031AD08006FE"
6 !
7 CLS "CBB":CALL COLOR("0CB")
8 LOCATE (5,8):PRINT "CHOISISSEZ VOTRE NIVEAU DE DIFFICULTE"
9 LOCATE (13,15):PRINT " 1 FACILE":LOCATE (14,15):PRINT "2 MOYEN"
10 LOCATE (15,15):PRINT " 3 DIFFICILE":LOCATE (16,15):PRINT "4 AMUSANT"
11 INPUT FO
12 !
13 CLS "RBB"
14 CALL COLOR("1MB")
15 LOCATE (6,39):PRINT CHR$(39):LOCATE (6,40):PRINT CHR$(40)
16 LOCATE (7,40):PRINT CHR$(41):LOCATE (7,39):PRINT CHR$(42)
17 !
18 N=.4-FO/10
19 PAUSE 5:RANDOMIZE
20 X=INTRND(10)+10:Y=2:V=0:H=0:A=3:B=0:CA=5000
21 X1=X:Y1=Y
22 H=H+1:X=X+V:Y=Y+H:IF X<2 THEN X=18
23 IF X>18 THEN X=2
24 IF Y<2 THEN Y=38:X=INTRND(10)+10
25 IF (Y>38 AND X<5)OR (Y>38 AND X>8)THEN Y=2:H=0
26 IF Y>37 AND X>=5 AND X<=8 AND H<4 THEN 55
27 IF Y>37 AND X>=5 AND X<=8 AND H>4 THEN Y=2:H=0
28 CALL COLOR("1YB"):LOCATE (X1,Y1):PRINT " "
29 LOCATE (X1-1,Y1):PRINT " ":LOCATE (X1+1,Y1):PRINT " "
30 LOCATE (X1,Y1-1):PRINT " ":LOCATE (X1,Y1+1):PRINT " "
31 IF A=1 THEN LOCATE (X,Y):PRINT CHR$(31):LOCATE (X+1,Y):PRINT CHR$(B)
32 IF A=2 THEN LOCATE (X,Y):PRINT CHR$(34):LOCATE (X-1,Y):PRINT CHR$(B)
33 IF A=3 THEN LOCATE (X,Y):PRINT CHR$(43):LOCATE (X,Y-1):PRINT CHR$(B)
34 IF A=4 THEN LOCATE (X,Y):PRINT CHR$(33):LOCATE (X,Y+1):PRINT CHR$(B)
35 PAUSE N
36 CALL KEY1(CC,TT)
37 IF CC=131 THEN A=4:B=32
38 IF CC=129 THEN A=3:B=32
39 IF CC=128 THEN A=1:B=32
40 IF CC=130 THEN A=2:B=32
41 IF CC=32 AND A=1 THEN V=V-1:B=35
42 IF CC=32 AND A=2 THEN V=V+1:B=38
43 IF CC=32 AND A=3 THEN H=H+2:B=36
44 IF CC=32 AND A=4 THEN H=H-2:B=37
45 IF B<>32 AND B<>0 THEN 46 ELSE 49
46 CALL SPEECH("L,"&B1$):CO=50
47 CA=CA-C0:IF CA<=0 THEN CA=0
48 LOCATE (21,1):PRINT CA:IF CA<=0 THEN 52 ELSE 21
49 CALL SPEECH("A,"):CO=0
50 GOTO 21
51 !
52 PAUSE 4:CALL SPEECH("A,"):CLS "CBB":CALL COLOR("0CB")
53 LOCATE (8,8):PRINT "VOUS N'AVEZ PLUS DE CARBURANT":GOTO 193
54 !
55 CALL SPEECH("A,"):PAUSE 4:CLS "CBB":CALL COLOR("0CB")
56 LOCATE (10,8):PRINT "BRAVO ! VOUS AVEZ REUSSI VOTRE MISE EN ORBITE."
57 LOCATE (13,8):PRINT "VOUS ETES MAINTENANT DANS LES ANNEAUX DE SATURNE ET :::"
58 LOCATE (16,8):PRINT "IL VOUS FAUT EVITER LES METEORITES."
59 LOCATE (20,15):PRINT "BONNE CHANCE ":PAUSE 7
60 !
61 CLS "RBB":RESTORE
62 FOR I=17 TO 24
63 CALL COLOR("1CB")
64 LOCATE (16,I):PRINT CHR$(23):NEXT
65 LOCATE (21,11):PRINT CHR$(21):LOCATE (20,12):PRINT CHR$(21)
66 LOCATE (19,13):PRINT CHR$(21):LOCATE (18,14):PRINT CHR$(21)
67 LOCATE (17,15):PRINT CHR$(21):LOCATE (16,16):PRINT CHR$(21)
68 LOCATE (21,30):PRINT CHR$(22):LOCATE (20,29):PRINT CHR$(22)
69 LOCATE (19,28):PRINT CHR$(22):LOCATE (18,27):PRINT CHR$(22)
70 LOCATE (17,26):PRINT CHR$(22):LOCATE (16,25):PRINT CHR$(22)
71 FOR I=12 TO 29:LOCATE (21,I):PRINT CHR$(23):NEXT
72 FOR I=13 TO 28:LOCATE (20,I):PRINT CHR$(23):NEXT
73 FOR I=14 TO 16:LOCATE (19,I):PRINT CHR$(23):NEXT
74 FOR I=25 TO 27:LOCATE (19,I):PRINT CHR$(23):NEXT
75 LOCATE (18,26):PRINT CHR$(25):LOCATE (18,15):PRINT CHR$(25)
76 CALL COLOR("1YB"):LOCATE (18,17):PRINT CHR$(24):LOCATE (18,19)
77 PRINT CHR$(24):LOCATE (18,22):PRINT CHR$(24):LOCATE (18,24):PRINT CHR$(24)
78 LOCATE (17,17):PRINT "SATURNE 3"
79 DATA 2,6,3,11,2,18,3,24,2,29,2,35,20,2,19,9,19,32,20,38
80 DATA 4,15,4,21,18,5,17,12,17,29,18,35
81 DATA 6,13,5,18,6,22,5,25,4,28,5,29,16,9,15,14,15,17,15,27,16,31
82 DATA 6,16,6,19,6,21,6,25,6,27,6,28,7,15,7,18,7,23
83 DATA 14,14,14,16,14,19,14,20,14,22,15,17,15,19,15,22,15,25,14,25
84 DATA 7,20,7,22,7,24,7,26,9,17,8,18,8,19,8,21,9,22,8,23,9,24,8,25
85 DATA 13,17,14,18,13,19,13,21,13,22,14,23,13,24,14,24,14,27
86 FOR I=1 TO 6:READ X,Y:CALL COLOR("1YB"):CALL AFF2(X,Y):NEXT
87 FOR I=1 TO 4:READ X,Y:CALL COLOR("1GB"):CALL AFF2(X,Y):NEXT
88 FOR I=1 TO 2:READ X,Y:CALL COLOR("1YB"):CALL AFF1(X,Y):NEXT
89 FOR I=1 TO 4:READ X,Y:CALL COLOR("1GB"):CALL AFF1(X,Y):NEXT
90 FOR I=1 TO 6:READ X,Y:CALL COLOR("1YB"):LOCATE (X,Y):PRINT CHR$(3):NEXT
91 FOR I=1 TO 5:READ X,Y:CALL COLOR("1GB"):LOCATE (X,Y):PRINT CHR$(3):NEXT
92 FOR I=1 TO 9:READ X,Y:CALL COLOR("1YB"):LOCATE (X,Y):PRINT CHR$(2):NEXT
93 FOR I=1 TO 10:READ X,Y:CALL COLOR("1GB"):LOCATE (X,Y):PRINT CHR$(2):NEXT
94 FOR I=1 TO 12:READ X,Y:CALL COLOR("1YB"):LOCATE (X,Y):PRINT CHR$(1):NEXT
95 FOR I=1 TO 9:READ X,Y:CALL COLOR("1GB"):LOCATE (X,Y):PRINT CHR$(1):NEXT
96 !
97 N=.7-FO/10:TEM=0:SA=0
98 RANDOMIZE
99 X=INTRND(2)+9
100 RANDOMIZE
101 Y=INTRND(4)+18:Y1=Y:Y2=Y:Y3=Y:Y4=Y:Y5=Y
102 !
103 CALL COLOR("0YB"):LOCATE (19,18):PRINT CA
104 CALL COLOR("1RB"):CALL SPEECH("R,"&B1$)
105 LOCATE (X,Y):PRINT CHR$(1):PAUSE N
106 IF SA=1 THEN 110
107 CALL KEY1(A,B)
108 IF A=131 THEN Y=Y-3:Y2=Y
109 IF A=129 THEN Y=Y+3:Y2=Y
110 !
111 LOCATE (X,Y1):PRINT " "
112 LOCATE (X,Y):PRINT CHR$(2):PAUSE N
113 IF SA=1 THEN 117
114 CALL KEY1(A,B)
115 IF A=131 THEN Y=Y-3:Y3=Y
116 IF A=129 THEN Y=Y+3:Y3=Y
117 !
118 LOCATE (X,Y2):PRINT " "
119 LOCATE (X,Y):PRINT CHR$(3):PAUSE N
120 IF SA=1 THEN 124
121 CALL KEY1(A,B)
122 IF A=131 THEN Y=Y-3:Y4=Y
123 IF A=129 THEN Y=Y+3:Y4=Y
124 !
125 LOCATE (X,Y3):PRINT " "
126 CALL AFF1(X,Y):PAUSE N-.3
127 IF SA=1 THEN 131
128 CALL KEY1(A,B)
129 IF A=131 THEN Y=Y-3:Y5=Y
130 IF A=129 THEN Y=Y+3:Y5=Y
131 IF Y-3>=7 AND Y+3<=33 THEN 141
132 CALL EFF(X,Y4)
133 CALL EFF(X,Y5)
134 CALL AFF2(X,Y)
135 PAUSE N
136 CALL EFF(X,Y)
137 TEM=TEM+1:IF TEM>20 THEN 148
138 CA=CA-50:IF CA<=0 THEN SA=1:CA=0
139 GOTO 98
140 !
141 CALL SPEECH("A,"&B1$):CALL SPEECH("L,"&EX$)
142 CLS "RRR":PAUSE .1:CLS "RYR":PAUSE .1:CLS "RbR":PAUSE .1:CLS "RMM"
143 PAUSE .1:CLS "RBB"
144 IF TEM<17 THEN 146 ELSE RANDOMIZE
145 Z=RND:IF Z>.7 THEN 152
146 CALL COLOR("0CB"):LOCATE (12,15):GOTO 190
147 !
148 CALL SPEECH("A,"):PAUSE 4:CLS "CBB":CALL COLOR("0CB")
149 LOCATE (12,15):PRINT "BRAVO !"
150 LOCATE (14,8):PRINT "MAINTENANT A VOUS POUR L'ATTERRISSAGE."
151 GOTO 155
152 CALL SPEECH("A,"):CALL COLOR("0CB"):LOCATE (12,8)
153 PRINT "VOUS AVEZ DE LA CHANCE,LES DEGATS SONT BENINS ET VOUS POURREZ";
154 PRINT "ATTERRIR."
155 PAUSE 5
156 !
157 CLS "CBB":CALL COLOR("0WB")
158 FOR I=1 TO 40
159 LOCATE (21,I):PRINT CHR$(29):NEXT
160 FOR I=18 TO 20
161 LOCATE (21,I):PRINT CHR$(12):NEXT
162 LOCATE (17,1):PRINT "VZ EC":LOCATE (17,36):PRINT "CA"
163 !
164 X=2:V=0:H=0:N=.4-FO/10:RANDOMIZE
165 L=RND:IF L>.5 THEN 166 ELSE 167
166 RANDOMIZE:Y=INTRND(10):GOTO 168
167 RANDOMIZE:Y=INTRND(10)+20
168 X1=X:Y1=Y
169 V=V+1:X=X+V:Y=Y+H:V1=V:SA=0
170 IF X<2 THEN X=2
171 IF X>19 AND Y=19 AND V<3 THEN 198
172 IF X>19 AND Y=19 AND V>3 THEN 189
173 IF X>19 AND Y<>19 THEN 189
174 CALL EFF1(X1,Y1):CALL AFF3(X,Y,B):PAUSE N
175 IF SA=1 THEN 187
176 CALL KEY1(A,B)
177 IF A=129 THEN H=H+1:B=32
178 IF A=131 THEN H=H-1:B=32
179 IF A=32 THEN V=V-2:B=30
180 IF V1-V<>2 THEN B=32
181 IF B<>32 THEN CALL SPEECH("L,"&B1$) ELSE CALL SPEECH("A,")
182 IF B=32 THEN CA=CA-CO
183 IF CA<=0 THEN SA=1:CA=0
184 LOCATE (18,34):PRINT CA
185 LOCATE (18,1):PRINT V;" "
186 EC=Y-19:LOCATE (18,4):PRINT EC
187 GOTO 168
188 !
189 CALL SPEECH("A,"):CLS "RRR":CALL SPEECH("L,"&EX$):PAUSE .1
190 CLS "CBB":CALL COLOR("0CB")
191 LOCATE (10,8):PRINT "VOTRE VAISSEAU EST DETRUIT"
192 !
193 LOCATE (12,8):PRINT "VOULEZ-VOUS REJOUER ? [O/N]"
194 RE$=KEY$
195 IF RE$="O" THEN 7
196 END
197 !
198 CALL SPEECH("A,"):PAUSE 4:CLS "CBB":CALL COLOR("0CB")
199 LOCATE (5,8):PRINT "VOTRE CONTRAT EST REMPLI ET VOTRE "
200 LOCATE (7,8):PRINT "DEXTERITE VOUS HONORE.":GOTO 193
201 !
202 SUB EFF(X,Y)
203 FOR I=-1 TO 1
204 LOCATE (X+I,Y):PRINT " "
205 LOCATE (X+I,Y-1):PRINT " "
206 LOCATE (X+I,Y+1):PRINT " ":NEXT
207 SUBEND
208 !
209 SUB AFF2(X,Y)
210 LOCATE (X,Y):PRINT CHR$(4)
211 LOCATE (X,Y+1):PRINT CHR$(5)
212 LOCATE (X-1,Y+1):PRINT CHR$(6)
213 LOCATE (X-1,Y):PRINT CHR$(7)
214 LOCATE (X-1,Y-1):PRINT CHR$(8)
215 LOCATE (X,Y-1):PRINT CHR$(9)
216 LOCATE (X+1,Y-1):PRINT CHR$(10)
217 LOCATE (X+1,Y):PRINT CHR$(11)
218 LOCATE (X+1,Y+1):PRINT CHR$(12)
219 SUBEND
220 !
221 SUB AFF1(X,Y)
222 LOCATE (X,Y):PRINT CHR$(4)
223 LOCATE (X,Y+1):PRINT CHR$(13)
224 LOCATE (X-1,Y+1):PRINT CHR$(14)
225 LOCATE (X-1,Y):PRINT CHR$(15)
226 LOCATE (X-1,Y-1):PRINT CHR$(16)
227 LOCATE (X,Y-1):PRINT CHR$(17)
228 LOCATE (X+1,Y-1):PRINT CHR$(18)
229 LOCATE (X+1,Y):PRINT CHR$(19)
230 LOCATE (X+1,Y+1):PRINT CHR$(20)
231 SUBEND
232 !
233 SUB AFF3(X,Y,B)
234 CALL COLOR("1YR"):LOCATE (X,Y):PRINT CHR$(27)
235 CALL COLOR("1YB"):LOCATE (X-1,Y):PRINT CHR$(26)
236 LOCATE (X,Y-1):PRINT CHR$(29):LOCATE (X,Y+1):PRINT CHR$(28)
237 CALL COLOR("1RB")
238 LOCATE (X+1,Y):PRINT CHR$(B)
239 SUBEND
240 !
241 SUB EFF1(X,Y)
242 FOR I=-1 TO 1
243 LOCATE (X,Y+I):PRINT CHR$(32):NEXT
244 LOCATE (X-1,Y):PRINT CHR$(32):LOCATE (X+1,Y):PRINT CHR$(32)
245 SUBEND
Ce listing est uniquement proposé pour un usage privé.
Sans accord écrit préalable, vous n'êtes pas autorisé à le distribuer, le transmettre ou le rediffuser.