1 !*********************************
4 !*** ****
7 !*** THE STRIFE ***
10 !*** LE CONFLIT ***
13 !*** LE 27/10/1986 ***
16 !*** POUR : EXEL 100 ***
19 !*** EN BASIC. TMS 7020 ***
22 !*** CREATEUR: SORTINO JF ***
25 !*** ***
28 !*** ***
31 !*********************************
34 !DEFINITION DES SONS
37 !
40 CLS:CALL HROFF:! ON NE SAIT JAMAIS
43 RANDOMIZE
46 R$="0BA02163031B18008D1E139840073A108100F0901E8108048078F084420020570"
49 Y$="CEBD02110840704E118840043CE0010F78C00316B080032C20010948800214A000"
52 V$="052800000000528000FC"
55 EXP$=R$&Y$&V$
58 !
61 ! +++++++DEFINITION DES CAR+++++++
64 !
67 CALL CHAR(1,"0000924C4CD5184C2810")
70 CALL CHAR(2,"0F0FC7E7FF7F07070F0F")
73 CALL CHAR(3,"80C0E0F0FEFFF0E0C080")
76 CALL CHAR(4,"01000003077FBFFFBF7F")
79 CALL CHAR(5,"808080E0F0FCFEFFFEFC")
82 CALL CHAR(6,"0703070F1F42FF7F3F1F")
85 CALL CHAR(7,"0080C0E0F008FFFEFCF8")
88 CALL CHAR(8,"0103070F7FFF0F070301")
91 CALL CHAR(9,"F0E1E3E7FFFEE0E0F0F0")
94 CALL CHAR(10,"00000038383838100000")
97 CALL CHAR(11,"10383838380000000000")
100 CALL CHAR(12,"3C181881DBDB8118183C")
103 CALL CHAR(13,"800000C0E0FEFDFFFDFE")
106 CALL CHAR(14,"010101070F3F7FFF7F3F")
109 !
112 ! +++DEFINITION VARIABLES***
115 !
118 X=2:Y=25:R=17:T=15:Q=9:S=20:S1=0:S1=0:GT=500
121 !
124 !
127 CALL COLOR("0YB"):PRINT " FAIT SORTINO JF"
130 CLS "RBB":K=12:L=1:Z=12:E=40
133 LOCATE (K,L):PRINT CHR$(0):LOCATE (Z,E):PRINT CHR$(0)
136 L=L+.5:E=E-.5
139 LOCATE (K,L):PRINT CHR$(25):LOCATE (Z,E):PRINT CHR$(23)
142 IF K=Z AND L=E THEN GOTO 544
145 GOTO 133
148 !
151 !+++PRESENTATION NO2+++
154 !
157 CLS "RBB":CALL COLOR("0RBHL")
160 LOCATE (10,10):PRINT "TTHHEE SSTTRRIIFFEE"
163 CALL COLOR("0GBHL"):LOCATE (11,10):PRINT "TTHHEE SSTTRRIIFFEE"
166 CALL COLOR("0bB"):LOCATE (13,15):PRINT "LE CONFLIT"
169 PAUSE 3:LOCATE (21,7):PRINT "FAIT PAR SORTINO JF"
172 CALL COLOR("1YBH"):LOCATE (15,5):PRINT "VOULEZ_VOUS LA FICHE TECHNIQUE"
175 LOCATE (16,5):PRINT "VOULEZ_VOUS LA FICHE TECHNIQUE"
178 A$=KEY$
181 IF A$="O" THEN CLS:GOTO 193
184 IF A$="N" THEN 220
187 IF A$<>"N"AND ASC(A$)<>27 AND A$<>"O" THEN 172
190 !+++FICHE TECHNIQUE+++
193 CALL COLOR("0MBL"):LOCATE (3,10):PRINT "TTHHEE SSTTRRIIFFEE"
196 CALL COLOR("1RB")
199 CALL COLOR("0GB"):LOCATE (7,3):PRINT "UTILISATION DES 2 MANETTES"
202 CALL COLOR("0CB"):LOCATE (9,3):PRINT "AVION : MANETTE AVEC BOUTON ORANGES"
205 LOCATE (10,3):PRINT "SOUS_MARIN : MANETTE AVEC BOUTON BLANC"
208 CALL COLOR("0bB"):LOCATE (12,3):PRINT "CREATEUR :** SORTINO JF **"
211 LOCATE (14,3):PRINT "(C) SORTINO JF.LE 20/02/85"
214 PAUSE 10
217 !++++REGLE DU JEU++++
220 CLS:CALL COLOR("0YRLF")
223 LOCATE (12,5):PRINT "VVOOUULLEEZZ__VVOOUUSS LLAA RREEGGLLEE"
226 A$=KEY$:IF A$="O" THEN 229 ELSE 280
229 CLS:CALL COLOR("0WRFI")
232 LOCATE (5,11):PRINT "REGLE DU JEU"
235 CALL COLOR("0Yb"):PRINT:PRINT "UN CONFIT REGNE : "
238 PRINT:PRINT "DES BATEAUX CHARGES DE DROGUE"
241 PRINT:PRINT "TRAVERSENT L'ATLANTIQUE,VOUS"
244 PRINT:PRINT "DEVREZ LES ABATTRE,MAIS VOUS"
247 PRINT:PRINT "ETES DEUX LES USA ET L'URSS."
250 PRINT:PRINT "VOUS MARQUEREZ 10 POINTS PAR "
253 PRINT:PRINT "BATEAU TOUCHE ET 5 PAR ENNEMI"
256 PRINT:PRINT "TOUCHE.............."
259 PRINT:PRINT "USA : AVION.****URSS : S_MARIN.****"
262 PRINT:PRINT TAB(5);"BONNE CHANCE !!!....."
265 PRINT TAB(7);"APPUYER SUR UNE TOUCHE"
268 A$=KEY$
271 !
274 !++++PRESENTATION JEU+++++
277 !
280 CLS "BbB":CALL COLOR("1CB")
283 CALL COLOR("1BC")
286 FOR A=1 TO 9:LOCATE (A,1):PRINT " "
289 NEXT A
292 CALL COLOR("1YB")
295 FOR I=1 TO 40:LOCATE (19,I):PRINT CHR$(160):NEXT I
298 CALL COLOR("1Gb")
301 FOR I=1 TO 12:LOCATE (18,INTRND(38)):PRINT CHR$(1):NEXT I
304 FOR I=20 TO 21:FOR A=1 TO 40:CALL COLOR("0G"):LOCATE (I,A):PRINT CHR$(160)
307 NEXT A:NEXT I
310 CALL COLOR("1BC"):LOCATE (X,Y):PRINT CHR$(2)
313 LOCATE (X,Y+1):PRINT CHR$(3)
316 LOCATE (Q,S):PRINT CHR$(6):LOCATE (Q,S+1):PRINT CHR$(7)
319 CALL COLOR("1Bb")
322 LOCATE (R,T):PRINT CHR$(4):LOCATE (R,T+1):PRINT CHR$(5)
325 !
328 !********TEST MANETTE**********
331 !
334 CALL KEY1(A,B):CALL KEY2(C,D)
337 IF A=129 THEN GOSUB 382
340 IF C=129 THEN GOSUB 400
343 IF A=131 THEN GOSUB 418
346 IF C=131 THEN GOSUB 436
349 IF A=32 THEN GOSUB 454
352 IF C=32 THEN GOSUB 499
355 TE=TE+1:IF TE=GT THEN GOTO 553
358 CALL COLOR("1YR")
361 LOCATE (20,5):PRINT "USA :";S1:LOCATE (20,31):PRINT "URSS :";S2
364 LOCATE (21,17):PRINT "TIME :";TE
367 CALL COLOR("1BC")
370 LOCATE (Q,S):PRINT CHR$(0):LOCATE (Q,S+1):PRINT CHR$(0):S=S+1
373 LOCATE (Q,S):PRINT CHR$(6):LOCATE (Q,S+1):PRINT CHR$(7)
376 IF S+1=40 THEN LOCATE (Q,S):PRINT CHR$(0):LOCATE (Q,S+1):PRINT CHR$(0):S=1
379 GOTO 334
382 !*************
385 CALL COLOR("1BC")
388 M=1:LOCATE (X,Y):PRINT CHR$(0):LOCATE (X,Y+1):PRINT CHR$(0)
391 Y=Y+M:LOCATE (X,Y):PRINT CHR$(2):LOCATE (X,Y+1):PRINT CHR$(3)
394 IF Y+1=40 THEN LOCATE (X,Y):PRINT CHR$(0):LOCATE (X,Y+1):PRINT CHR$(0):Y=1
397 RETURN
400 !*************
403 CALL COLOR("1Bb")
406 M=1:LOCATE (R,T):PRINT CHR$(0):LOCATE (R,T+1):PRINT CHR$(0)
409 T=T+M:LOCATE (R,T):PRINT CHR$(4):LOCATE (R,T+1):PRINT CHR$(5)
412 IF T+1=40 THEN LOCATE (R,T):PRINT CHR$(0):LOCATE (R,T+1):PRINT CHR$(0):T=1
415 RETURN
418 !************
421 CALL COLOR("1BC")
424 M=-1:LOCATE (X,Y):PRINT CHR$(0):LOCATE (X,Y+1):PRINT CHR$(0)
427 Y=Y+M:LOCATE (X,Y):PRINT CHR$(8):LOCATE (X,Y+1):PRINT CHR$(9)
430 IF Y=1 THEN LOCATE (X,Y):PRINT CHR$(0):LOCATE (X,Y+1):PRINT CHR$(0):Y=39
433 RETURN
436 !***********
439 CALL COLOR("1Bb")
442 M=-1:LOCATE (R,T):PRINT CHR$(0):LOCATE (R,T+1):PRINT CHR$(0)
445 T=T+M:LOCATE (R,T):PRINT CHR$(14):LOCATE (R,T+1):PRINT CHR$(13)
448 IF T=1 THEN LOCATE (R,T):PRINT CHR$(0):LOCATE (R,T+1):PRINT CHR$(0):T=39
451 RETURN
454 !***********
457 I=X+1:F=Y:CO$="1RC"
460 CALL COLOR(CO$)
463 LOCATE (I,F):PRINT CHR$(0):I=I+1:LOCATE (I,F):PRINT CHR$(10)
466 IF I=R AND F=T THEN CALL SPEECH("L,"&EXP$):LOCATE (I,F):PRINT CHR$(12)
469 IF I=R AND F=T THEN PAUSE 1:LOCATE (I,F):PRINT CHR$(0):S1=S1+5:RETURN
472 IF I=17 THEN LOCATE (I,F):PRINT CHR$(0):RETURN
475 IF I=Q AND F=S THEN CALL SPEECH("L,"&EXP$):LOCATE (I,F):PRINT CHR$(12)
478 IF I=Q AND F=S THEN PAUSE 1:LOCATE (I,F):PRINT CHR$(0):S1=S1+10:RETURN
481 IF I=10 THEN CO$="1Rb"
484 CALL COLOR("1BC")
487 LOCATE (Q,S):PRINT CHR$(0):LOCATE (Q,S+1):PRINT CHR$(0):S=S+1
490 LOCATE (Q,S):PRINT CHR$(6):LOCATE (Q,S+1):PRINT CHR$(7)
493 IF S+1=40 THEN LOCATE (Q,S):PRINT CHR$(0):LOCATE (Q,S+1):PRINT CHR$(0):S=1
496 GOTO 460
499 !**********
502 O=R-1:P=T:CO$="1Rb"
505 CALL COLOR(CO$)
508 LOCATE (O,P):PRINT CHR$(0):O=O-1:LOCATE (O,P):PRINT CHR$(11)
511 IF O=9 THEN CO$="1RC"
514 IF O=X AND P=Y THEN CALL SPEECH("L,"&EXP$):LOCATE (O,P):PRINT CHR$(12)
517 IF O=X AND P=Y THEN PAUSE 1:LOCATE (O,P):PRINT CHR$(0):S2=S2+5:RETURN
520 IF O=2 THEN LOCATE (O,P):PRINT CHR$(0):RETURN
523 IF O=Q AND P=S THEN CALL SPEECH("L,"&EXP$):LOCATE (O,P):PRINT CHR$(12)
526 IF O=Q AND P=S THEN PAUSE 1:LOCATE (O,P):PRINT CHR$(0):S2=S2+10:RETURN
529 CALL COLOR("1BC")
532 LOCATE (Q,S):PRINT CHR$(0):LOCATE (Q,S+1):PRINT CHR$(0):S=S+1
535 LOCATE (Q,S):PRINT CHR$(6):LOCATE (Q,S+1):PRINT CHR$(7)
538 IF S+1=40 THEN LOCATE (Q,S):PRINT CHR$(0):LOCATE (Q,S+1):PRINT CHR$(0):S=1
541 GOTO 505
544 !*********
547 FOR I=1 TO 5:CALL SPEECH("L,"&EXP$):CLS "RRR":CLS "YYY":NEXT I
550 GOTO 157
553 !*********
556 CLS "RbC":CALL COLOR("0RC")
559 LOCATE (5,12):PRINT "LA PARTIE SE TERMINE"
562 LOCATE (12,15):PRINT "USA : ";S1
565 LOCATE (14,15):PRINT "URSS : ";S2
568 IF S1>S2 THEN LOCATE (16,6):PRINT "LES USA SONT DECLARE VAINQUEUR"
571 IF S1<S2 THEN LOCATE (16,6):PRINT "L'URSS EST DECLAREE VAINQUEUR"
574 LOCATE (18,12):PRINT "UNE AUTRE PARTIE"
577 A$=KEY$
580 IF A$="O"OR A$="OUI" THEN 280 ELSE GOTO 586
581 ! FIN
583 END
586 !********
589 CLS "GBB"
592 CALL COLOR("0RBLHF")
595 LOCATE (12,10):PRINT "BBYYEE"
598 LOCATE (13,10):PRINT "BBYYEE"
601 CALL COLOR("0GBLHF")
604 LOCATE (12,18):PRINT "BBYYEE"
607 LOCATE (13,18):PRINT "BBYYEE"
610 CALL COLOR("0YBLHF")
613 LOCATE (12,26):PRINT "!!"
616 LOCATE (13,26):PRINT "!!"
619 PAUSE 8
622 CLS "CCC":PAUSE 1:CLS "RRR":PAUSE 1:CLS "RGB"
625 !********************************
628 !
Ce listing est uniquement proposé pour un usage privé.
Sans accord écrit préalable, vous n'êtes pas autorisé à le distribuer, le transmettre ou le rediffuser.