1 !____________________________________!
2 !************************************!
3 ! JEAN-LUC !
4 ! FREDERIC !
5 ! PRESENTENT !
6 ! POUR EXEL 100 !
7 ! ZOMBIE !
8 !************************************!
9 !____________________________________!
10 !+++++++++++++++++++++++++++++++++++!
11 ! GRAPHISME !
12 !+++++++++++++++++++++++++++++++++++!
13 CALL CHAR(37,"00003C5AFFFF81C3663C")
14 CALL CHAR(38,"0042C324181824C24200")
15 CALL CHAR(65,"FFFFC0C0C3C7CECCC0C0")
16 CALL CHAR(66,"FFFF0303C3C3C3C3C3C3")
17 CALL CHAR(67,"C0C0C0C0C1C7C0C0FFFF")
18 CALL CHAR(68,"C3C3C3C3E3FB0303FFFF")
19 CALL CHAR(69,"00000000000303000000")
20 CALL CHAR(70,"0000000000FFFF03070E")
21 CALL CHAR(71,"0000000000FFFF800000")
22 CALL CHAR(72,"0000000080C1E37F3E1C")
23 CALL CHAR(73,"1C383870E0C080000000")
24 CALL CHAR(74,"0F1F3C7878E0C0C0C0C0")
25 CALL CHAR(75,"F0F83C1E1E0703030303")
26 CALL CHAR(76,"C0C0C0E0F070381C0F07")
27 CALL CHAR(77,"030303070F0E1C38F0E0")
28 CALL CHAR(78,"C0C0C0C0C0C0C0C0C0C0")
29 CALL CHAR(79,"03030303030303030303")
30 CALL CHAR(80,"C0C0C0E0F078381C0F07")
31 CALL CHAR(81,"030303070F1E1C38F8F0")
32 CALL CHAR(82,"0F1F3C7878E0C0C0C0FF")
33 CALL CHAR(83,"F0F83C1E1E07030303FF")
34 CALL CHAR(84,"FFC0C0E0F070381C0F07")
35 CALL CHAR(85,"FF000000000E1C38F8F0")
36 CALL CHAR(86,"FFFFC0C0C0C0C0C0C0FF")
37 CALL CHAR(87,"F0F81C0C0E07070303FF")
38 CALL CHAR(88,"FFC0C0C0C0C0C0C0C0C0")
39 CALL CHAR(89,"FF703038181C0C0E0703")
40 CALL CHAR(49,"1F1F38387070E0E0E0FF")
41 CALL CHAR(50,"FFFF00000000000000FF")
42 CALL CHAR(51,"FF00000000000000FFFF")
43 CALL CHAR(52,"FF0707070E0E0E0CFCFC")
44 CALL CHAR(53,"FFFFC0C0CFCFCCCCC1C3")
45 CALL CHAR(54,"FFFF0303F3F373F3E3C3")
46 CALL CHAR(55,"C7CFCECECFCFC0C0FFFF")
47 CALL CHAR(56,"83030303F3F30303FFFF")
48 !
49 ! INITIALISATIONS DES SONS
50 !
51 CALL POKE(50688,165,8,6,10)!====STOCKAGE ROUTINE TIMER CODE MACHINE======!
52 CALL POKE(49156,198,0)!=======INIT VECTEUR INTERRUPT TIMER========!
53 !
54 ! DISPARITION DE LA 1 LIGNE
55 !
56 CALL POKE(50432,162,5,45,162,136,45,10,162,5,45,162,200,45,10)
57 !
58 ! EXPLOSION
59 !
60 A1$="0BA02163031B18008D1E139840073A108100F0901E81080480478F084420020570"
61 A2$="CEBD02110840704E118840043CE0010F78C00316B080052C20010948800214A0000528"
62 EX$=A1$&A2$
63 !
64 ! #####PRESENTATION#############
65 !
66 CALL EXEC(50432):CLS "CBB":CALL SON:CALL CADRE
67 CALL COLOR("0WB")
68 FOR I=2 TO 10
69 LOCATE (2,I)
70 PRINT " JEAN-LUC & FREDERIC"
71 NEXT:CALL ZAP(1)
72 FOR I=2 TO 16
73 LOCATE (4,I)
74 PRINT " FARGES"
75 NEXT:CALL ZAP(2)
76 CALL COLOR("0CB")
77 FOR I=2 TO 14
78 LOCATE (7,I)
79 PRINT " PRESENTENT"
80 NEXT:CALL ZAP(3)
81 DIM Z$(6)
82 Z$(1)="Z":Z$(2)="0"
83 Z$(3)="M":Z$(4)="B"
84 Z$(5)="I":Z$(6)="E"
85 FOR I=1 TO 6:CALL BEEP(1)
86 FOR J=36 TO 12+2*I STEP -2
87 CALL COLOR("0CBHL")
88 FOR B=1 TO 40:NEXT
89 LOCATE (10,J)
90 PRINT Z$(I);Z$(I);" "
91 CALL COLOR("0bBHL")
92 LOCATE (11,J)
93 PRINT Z$(I);Z$(I);" "
94 NEXT
95 NEXT
96 CALL COLOR("0bB")
97 CALL SPEECH("L,"&EX$)
98 LOCATE (18,4)
99 PRINT "VOULEZ-VOUS LES REGLES DU JEU?"
100 LOCATE (19,16):PRINT "(0=N 1=O)"
101 RE$=KEY$
102 IF RE$="1" THEN CALL FIN:CALL SPEECH("L,"&EX$):GOTO 106
103 IF RE$="0" THEN CALL BEEP(5):GOTO 137
104 GOTO 101
105 !
106 ! REGLES DU JEU
107 !
108 CALL EFF:CALL COLOR("0RBL")
109 LOCATE (2,7):PRINT "RREEGGLLEESS DDUU JJEEUU"
110 DIM M$(18)
111 M$(2)=" BONJOUR,VOUS ETES UN PETIT GLOUTON"
112 M$(3)=" QUI SE TROUVE DANS UN CIMETIERE OU LA"
113 M$(4)=" DEVANT VOUS,VOUS APERCEVEZ D'HORRI-"
114 M$(5)=" BLES CREATURES LES ZOMBIES QUI PAR"
115 M$(6)=" TOUS LES MOYENS,ESSAIERONT DE VOUS"
116 M$(7)=" DEVORER.POUR EVITER LE DRAME, ATTIREZ"
117 M$(8)=" LES VERS LES ZIMANGES,VOS AMIS,"
118 M$(9)=" QUI SE FERONT RARES A L'AVENIR."
119 M$(10)=" ATTENTION CERTAINS NE SONT QU'ILLUSION"
120 M$(11)=" ET IL VOUS ARRIVERA MEME DE VOIR DES"
121 M$(12)=" ZOMBIES RENAITRE DE LEURS CENDRES."
122 M$(13)=" SOYEZ VIGILANT SINON VOUS REJOINDREZ"
123 M$(14)=" LE ROYAUME DES MORTS."
124 M$(15)=" DIRECTION:"
125 M$(16)=" LES DEUX MANETTES"
126 M$(17)=" OU LE CLAVIER"
127 M$(18)=" RETURN POUR CONTINUER S.V.P"
128 FOR I=1 TO 18
129 FOR J=2 TO LEN(M$(I))
130 CALL COLOR("0RB")
131 LOCATE (I+1,J):PRINT CHR$(95)
132 CALL COLOR("0GB")
133 CALL ZAP(5):LOCATE (I+1,J):PRINT SEG$(M$(I),J,1)
134 NEXT:CALL SON
135 NEXT
136 PAUSE
137 ! !
138 !__________________________________!
139 ! OPTIONS !
140 !__________________________________!
141 !
142 CALL EFF:CALL SON:CALL SON
143 CALL COLOR("0YBL")
144 LOCATE (2,3)
145 PRINT "CCHHOOIIXX DDEESS OOPPTTIIOONNSS"
146 FOR I=2 TO 39:CALL COLOR("0bB")
147 LOCATE (3,I)
148 PRINT CHR$(4)
149 NEXT
150 CALL COLOR("0GBH")
151 LOCATE (7,6)
152 PRINT "NOMBRE DE JOUEUR ? (1/2)"
153 CALL COLOR("0bBH")
154 LOCATE (8,6)
155 PRINT "NOMBRE DE JOUEUR ? (1/2)"
156 NB$=KEY$
157 IF NB$="1" THEN NBR=1:GOTO 160
158 IF NB$="2" THEN NBR=2:GOTO 161
159 GOTO 156
160 CALL JOUEUR:PAUSE 2:GOTO 162
161 CALL JOUEURS:PAUSE 2:GOTO 177
162 FOR I=5 TO 19:CALL COLOR("0BB")
163 LOCATE (I,2):PRINT " "
164 NEXT
165 CALL COLOR("0CBHL")
166 LOCATE (9,10):PRINT "VVOOTTRREE NNOOMM"
167 CALL COLOR("0bBHL")
168 LOCATE (10,10):PRINT "VVOOTTRREE NNOOMM"
169 CALL COLOR("0CB"):LOCATE (21,2)
170 INPUT NOM$:CALL ZAP(6):CALL COLOR("0B"):LOCATE (21,1):PRINT RPT$(" ",40)
171 IF LEN(NOM$)>13 OR LEN(NOM$)<=0 THEN NOM$="PETIT GLOUTON"
172 CALL COLOR("0B"):LOCATE (21,2):PRINT RPT$(" ",38)
173 CALL COLOR("0GBH")
174 LOCATE (11,(40-LEN(NOM$))/2):PRINT NOM$
175 CALL COLOR("0bBH")
176 LOCATE (12,(40-LEN(NOM$))/2):PRINT NOM$
177 CALL SON:PAUSE .1:CALL SPEECH("L,"&EX$)
178 FOR I=5 TO 19:CALL COLOR("0BB")
179 LOCATE (I,2):PRINT " ":NEXT
180 IF NBR=1 THEN CALL AFFOPT ELSE 195
181 CALL COLOR("0CBH")
182 MES$="VOTRE CHOIX "&NOM$&" ?"
183 LOCATE (15,(40-LEN(MES$))/2):PRINT MES$
184 CALL COLOR("0bBH")
185 LOCATE (16,(40-LEN(MES$))/2):PRINT MES$
186 CALL COLOR("0RBLF"):OUI$=KEY$
187 IF OUI$="1" THEN V(1)=3:GOTO 191
188 IF OUI$="2" THEN V(1)=2:GOTO 192
189 IF OUI$="3" THEN V(1)=1:GOTO 193
190 GOTO 186
191 LOCATE (9,2):PRINT "11::DDEEBBUUTTAANNTT..................":GOTO 194
192 LOCATE (10,2):PRINT "22::AAMMAATTEEUURR....................":GOTO 194
193 LOCATE (11,2):PRINT "33::PPRROOFFEESSSSIIOONNNNEELL........"
194 PAUSE 2:GOTO 213
195 CALL AFFOPT
196 O=1
197 IF O>2 THEN CLS:GOTO 213
198 CALL COLOR("0CBH")
199 LOCATE (14,4):PRINT "JOUEUR ";O;" VOTRE CHOIX ?"
200 CALL COLOR("0bBH")
201 LOCATE (15,4):PRINT "JOUEUR ";O;" VOTRE CHOIX ?"
202 CALL COLOR("0CBL"):OUI$=KEY$
203 IF OUI$="1" THEN V(O)=3:GOTO 207
204 IF OUI$="2" THEN V(O)=2:GOTO 208
205 IF OUI$="3" THEN V(O)=1:GOTO 209
206 GOTO 202
207 LOCATE (16,2):PRINT "11::DDEEBBUUTTAANNTT..................":GOTO 210
208 LOCATE (16,2):PRINT "22::AAMMAATTEEUURR....................":GOTO 210
209 LOCATE (16,2):PRINT "33::PPRROOFFEESSSSIIOONNNNEELL........":GOTO 210
210 PAUSE 2:CALL COLOR("0B"):LOCATE (16,2)
211 PRINT " ":O=O+1
212 GOTO 197
213 !
214 ! MUSIQUE DU DEPLACEMENT
215 !
216 RESTORE 217:FOR II=1 TO 10:READ SO(II):NEXT
217 DATA 150,180,155,107,183,116,145,167,149,199
218 II=1
219 !
220 !EMBRANCHEMENT SUR LES PROGRAMMES
221 !D'INITIALISATION DES TABLEAUX
222 !
223 DIM T(20,22)
224 J=1:C(1)=6:C(2)=14
225 TA(1)=1:TA(2)=1:AIE(1)=5:AIE(2)=5
226 FOR I=1 TO 10:T(YZI(I),XZI(I))=0:NEXT
227 IF TA(J)<13 THEN 232
228 TA(J)=TA(J)-12
229 ON TA(J)GOSUB 448,461,473,485,497,509,521
230 TA(J)=TA(J)+12
231 GOTO 233
232 ON TA(J)GOSUB 301,313,325,337,349,361,373,386,398,410,422,435
233 !
234 ! CHARGEMENT DU TABLEAU
235 !
236 CLS "CBB":CALL COLOR("1WB")
237 LOCATE (1,1):PRINT "&&&&&&&&&&&&&&&&&&&&&&&"
238 LOCATE (21,1):PRINT "&&&&&&&&&&&&&&&&&&&&&&&"
239 FOR I=2 TO 20
240 LOCATE (I,1):PRINT "&"
241 LOCATE (I,23):PRINT "&"
242 NEXT
243 CALL COLOR("1YB")
244 LOCATE (YJ,XJ):PRINT "%"
245 CALL COLOR(CZI$)
246 FOR I=1 TO ZI
247 LOCATE (YZI(I),XZI(I)):PRINT "$"
248 T(YZI(I),XZI(I))=1
249 NEXT
250 !__________________________________!
251 !AFFICHAGE DES ZIMANGES ILLUSION !
252 !QUI NE PEUVENT DETRUIRE LES !
253 ! ZOMBIES !
254 !__________________________________!
255 FOR I=1 TO AIE(J):RANDOMIZE:X=INTRND(10):Y=INTRND(9)
256 LOCATE (2*Y+1,2*X+1):PRINT "$"
257 NEXT
258 CALL COLOR(CZO$)
259 FOR I=1 TO ZO
260 LOCATE (YZO(I),XZO(I))
261 PRINT "#"
262 NEXT
263 IF NBR=1 THEN CALL SCORE(NOM$) ELSE CALL BOBO
264 CALL COLOR("1YB"):LOCATE (C(1)+1,28):PRINT RPT$("%",V(1))
265 IF NBR=2 THEN LOCATE (C(2)+1,28):PRINT RPT$("%",V(2))
266 CALL COLOR("0GBH"):LOCATE (4,30):PRINT S(1)
267 CALL COLOR("0bBH"):LOCATE (5,30):PRINT S(1)
268 IF NBR=1 THEN 271
269 CALL COLOR("0GBH"):LOCATE (12,30):PRINT S(2)
270 CALL COLOR("0bBH"):LOCATE (13,30):PRINT S(2)
271 !
272 ! JEU
273 CALL COLOR("0RBH"):LOCATE (20,25):PRINT TA(J):LOCATE (21,25):PRINT TA(J)
274 CALL COLOR("1BB"):LOCATE (YJ,XJ):PRINT " "
275 IF J=1 THEN CALL KEY1(A,B):GOTO 277
276 IF J=2 THEN CALL KEY2(A,B)
277 XJ=XJ+2*(A=131 AND XJ>2)-2*(A=129 AND XJ<22)
278 YJ=YJ+2*(A=128 AND YJ>2)-2*(A=130 AND YJ<20)
279 CALL COLOR("1YB"):LOCATE (YJ,XJ):PRINT "%"
280 I=1
281 IF YZO(I)=100 THEN I=I+1:GOTO 281
282 CALL COLOR("0BB"):LOCATE (YZO(I),XZO(I)):PRINT " "
283 XZO(I)=XZO(I)+SGN(XJ-XZO(I))
284 YZO(I)=YZO(I)+SGN(YJ-YZO(I))
285 IF T(YZO(I),XZO(I))=1 THEN 534
286 IF (XZO(I)=XJ AND YZO(I)=YJ)THEN 545
287 CALL COLOR(CZO$)
288 LOCATE (YZO(I),XZO(I)):PRINT "#"
289 CALL POKE(258,SO(II),132)
290 IF II=10 THEN II=0
291 II=II+1
292 S(J)=S(J)+1
293 CALL COLOR("0GBH"):LOCATE (C(J)-1,30):PRINT S(J)
294 CALL COLOR("0bBH"):LOCATE (C(J)-2,30):PRINT S(J)
295 I=I+1
296 IF I>ZO THEN 274
297 GOTO 281
298 !
299 ! 1e TABLEAU
300 !
301 ZI=5:ZO=2
302 XJ=4:YJ=10:XZI(1)=3:YZI(1)=5:XZI(2)=3:YZI(2)=17:XZI(3)=13:YZI(3)=9
303 XZI(4)=19:YZI(4)=12:XZI(5)=11:YZI(5)=18
304 XZO(1)=17:YZO(1)=2:XZO(2)=17:YZO(2)=18
305 CALL CHAR(35,"7E6FF7BD7E243C42817E")!++++++++++++UN PETIT ZOMBIE
306 CALL CHAR(36,"815A3C5AFF8142245A81")!+++++++++++++++PETIT ZIMANGE
307 CZI$="1RB"
308 CZO$="1bB"
309 RETURN
310 !
311 ! 2eme TABLEAU
312 !
313 ZI=4:ZO=3
314 XJ=4:YJ=16:XZI(1)=11:YZI(1)=19:XZI(2)=17:YZI(2)=13:XZI(3)=17:YZI(3)=9
315 XZI(4)=21:YZI(4)=3
316 XZO(1)=2:YZO(1)=2:XZO(2)=2:YZO(2)=12:XZO(3)=2:YZO(3)=19
317 CALL CHAR(35,"4224FFBD7E66423C1818")!++++++++UN AUTRE PETIT ZOMBIE
318 CALL CHAR(36,"00C324187EC3E77E1866")!+++++++++UN AUTRE PETIT ZIMANGE
319 CZI$="1YB"
320 CZO$="1GB"
321 RETURN
322 !
323 ! 3eme TABLEAU
324 !
325 ZI=5:ZO=4
326 XJ=2:YJ=2:XZI(1)=11:YZI(1)=7:XZI(2)=19:YZI(2)=7:XZI(3)=15:YZI(3)=9
327 XZI(4)=11:YZI(4)=19:XZI(5)=19:YZI(5)=19:XZO(1)=2:YZO(1)=19:XZO(2)=10
328 YZO(2)=19:XZO(3)=19:YZO(3)=19:XZO(4)=20:YZO(4)=2
329 CALL CHAR(35,"7EBD99FF7E3C66427E3C")!++++++++++UN AUTRE PETIT ZOMBIE
330 CALL CHAR(36,"3C42A581BD99423C42C3")!+++++++++UN AUTRE PETIT ZIMANGE
331 CZI$="1MB"
332 CZO$="1WB"
333 RETURN
334 !
335 ! 4eme TABLEAU
336 !
337 ZI=4:ZO=3
338 XJ=12:YJ=18:XZI(1)=2:YZI(1)=5:XZI(2)=17:YZI(2)=8:XZI(3)=2:YZI(3)=19
339 XZI(4)=17:YZI(4)=18:XZO(1)=11:YZO(1)=18:XZO(2)=13:YZO(2)=18
340 XZO(3)=12:YZO(3)=19
341 CZI$="1CB"
342 CZO$="1bB"
343 CALL CHAR(35,"7EBD99FFFF7E66427E3C")!++++++++++UN AUTRE PETIT ZOMBIE
344 CALL CHAR(36,"183C7EBDFFC3E77E7E81")!+++++++++++UN AUTRE PETIT ZIMANGE
345 RETURN
346 !
347 ! 5eme TABLEAU
348 !
349 ZI=3:ZO=4
350 XJ=12:XJ=18:XZI(1)=5:YZI(1)=5:XZI(2)=5:YZI(2)=17:XZI(3)=19:YZI(3)=13
351 XZO(1)=15:YZO(1)=5:XZO(2)=5:YZO(2)=13:XZO(3)=19:YZO(3)=17
352 XZO(4)=13:YZO(4)=3
353 CZI$="1CB"
354 CZO$="1WB"
355 CALL CHAR(35,"3C7EDBFFFFE7C3FFFFDB")!++++++++++++UN AUTRE PETIT ZOMBIE
356 CALL CHAR(36,"4224FFDB7E42243C1818")!++++++++++++++UN AUTRE PETIT ZIMANGE
357 RETURN
358 !
359 ! 6eme TABLEAU
360 !
361 ZI=2:ZO=4
362 XJ=2:YJ=18:XZI(1)=13:YZI(1)=3:XZI(2)=13:YZI(2)=19
363 XZO(1)=13:YZO(1)=5:XZO(2)=13:YZO(2)=17:XZO(3)=3:YZO(3)=9
364 XZO(4)=21:YZO(4)=9
365 CZI$="1RB"
366 CZO$="1GB"
367 CALL CHAR(35,"42FF7E427E66423C5A81")!++++++++++++UN AUTRE PETIT ZOMBIE
368 CALL CHAR(36,"3C5AFFC30000C3FF7E3C")!++++++++++++++UN AUTRE PETIT ZIMANGE
369 RETURN
370 !
371 ! 7eme TABLEAU
372 !
373 ZI=2:ZO=4
374 XJ=2:YJ=2
375 XZI(1)=5:YZI(1)=5:XZI(2)=9:YZI(2)=9
376 XZO(1)=19:YZO(1)=19:XZO(2)=17:YZO(2)=19:XZO(3)=15:YZO(3)=19
377 XZO(4)=13:YZO(4)=19
378 CALL CHAR(35,"1818FFDBFF3C3C243C3C")!++++++++++++++++UN AUTRE PETIT ZOMBIE
379 CALL CHAR(36,"243C7EFF81C3E77E3CC3")!++++++++++++++++UN AUTRE PETIT ZIMANGE
380 CZI$="1MB"
381 CZO$="1YBF"
382 RETURN
383 !
384 ! 8eme TABLEAU
385 !
386 ZI=1:ZO=3
387 XJ=14:YJ=12
388 XZI(1)=11:YZI(1)=15
389 XZO(1)=3:YZO(1)=3:XZO(2)=19:YZO(2)=3:XZO(3)=9:YZO(3)=19
390 CALL CHAR(35,"007E9999FF6642BDFFFF")!+++++++++++++++++++UN PETIT ZOMBIE
391 CALL CHAR(36,"24183C7EFF42663C24C3")!++++++++++++++++++UN AUTRE ZIMANGE
392 CZI$="1CB"
393 CZO$="1bB"
394 RETURN
395 !
396 ! 9eme TABLEAU
397 !
398 ZI=1:ZO=4
399 XJ=14:YJ=8
400 XZI(1)=13:YZI(1)=9
401 XZO(1)=2:YZO(1)=2:XZO(2)=20:YZO(2)=2:XZO(3)=2:YZO(3)=20:XZO(4)=20:YZO(4)=20
402 CALL CHAR(35,"60103FCFF71818181818")!++++++++++++++++UN AUTRE ZOMBIE
403 CALL CHAR(36,"007E9999FF7E183C42E7")!++++++++++++++++++++UN AUTRE ZIMANGE
404 CZI$="1GBF"
405 CZO$="1WBF"
406 RETURN
407 !
408 ! 10eme TABLEAU
409 !
410 ZI=1:ZO=3
411 XJ=4:YJ=4
412 XZI(1)=5:YZI(1)=5
413 XZO(1)=10:YZO(1)=10:XZO(2)=15:YZO(2)=10:XZO(3)=15:YZO(3)=15
414 CALL CHAR(35,"183C243C7E66C3FFAB00")!++++++++++++++++UN PETIT ZOMBIE
415 CALL CHAR(36,"81423C667E42663C4281")!++++++++++++++++++UN PETIT ZIMANGE
416 CZI$="1MBF"
417 CZO$="1GBF"
418 RETURN
419 !
420 ! 11eme TABLEAU
421 !
422 ZI=3:ZO=5
423 XJ=10:YJ=10
424 XZI(1)=3:YZI(1)=3:XZI(2)=13:YZI(2)=3:XZI(3)=19:YZI(3)=3
425 XZO(1)=9:YZO(1)=10:XZO(2)=11:YZO(2)=10:XZO(3)=10:YZO(3)=9
426 XZO(4)=2:YZO(4)=19:XZO(5)=19:YZO(5)=19
427 CALL CHAR(35,"7EBDE7C3FF244242C300")!++++++++++++++++++++UN PETIT ZOMBIE
428 CALL CHAR(36,"7EDBFF663C1818183C7E")!++++++++++++++++UN PETIT ZIMANGE
429 CZI$="1bB"
430 CZO$="1GB"
431 RETURN
432 !
433 ! 12eme TABLEAU
434 !
435 ZI=1:ZO=4
436 XJ=16:YJ=16
437 XZI(1)=5:YZI(1)=17
438 XZO(1)=16:YZO(1)=15:XZO(2)=17:YZO(2)=16:XZO(3)=16:YZO(3)=17
439 XZO(4)=14:YZO(4)=18
440 CALL CHAR(35,"2294496A6A7E7E665A3C")!++++++++++++++UN PETIT ZOMBIE
441 CALL CHAR(36,"C3C33C5AFFDBE7FF6666")!+++++++++++++++++++UN PETIT ZIMANGE
442 CZI$="1YBF"
443 CZO$="1MBF"
444 RETURN
445 !
446 ! 13eme TABLEAU
447 !
448 Z1=1:ZO=5
449 XJ=12:YJ=12
450 XZI(1)=3:YZI(1)=5
451 XZO(1)=11:YZO(1)=12:XZO(2)=13:YZO(2)=12:XZO(3)=12:YZO(3)=11
452 XZO(4)=3:YZO(4)=19:XZO(5)=20:YZO(5)=19
453 CALL CHAR(36,"7EFFDBFFDBE77E1824C3")!++++++++++++++++++++UN PETIT ZIMANGE
454 CALL CHAR(35,"42C3245AFFE7DB3CC342")!+++++++++++++++++++++++UN PETIT ZOMBIE
455 CZI$="1CBF"
456 CZO$="1WBF"
457 RETURN
458 !
459 ! 14eme TABLEAU
460 !
461 ZI=2:ZO=3
462 XJ=2:YJ=2
463 XZI(1)=5:YZI(1)=9:XZI(2)=17:YZI(2)=17
464 XZO(1)=20:YZO(1)=2:XZO(2)=10:YZO(2)=3:XZO(3)=5:YZO(3)=3
465 CALL CHAR(35,"001F2A7C7C643A1E3E7C")!+++++++++++++++++++UN PETIT ZOMBIE
466 CALL CHAR(36,"7EFF9999FFFFDB663C18")!+++++++++++++UN PETIT ZIMAMGE
467 CZI$="1WBF"
468 CZO$="1RBF"
469 RETURN
470 !
471 ! 15eme TABLEAU
472 !
473 ZI=2:ZO=3
474 XJ=12:YJ=12
475 XZI(1)=11:YZI(1)=3:XZI(2)=15:YZI(2)=13
476 XZO(1)=19:YZO(1)=3:XZO(2)=5:YZO(2)=15:XZO(3)=19:YZO(3)=19
477 CALL CHAR(35,"004166001800187E0000")!++++++++++++++UN PETIT ZOMBIE
478 CALL CHAR(36,"0042101018007E3C0000")!++++++++++++++UN PETIT ZIMANGE
479 CZI$="1YBF"
480 CZO$="1GB"
481 RETURN
482 !
483 ! 16 eme TABLEAU
484 !
485 ZI=2:ZO=3
486 XJ=12:YJ=12
487 XZI(1)=13:YZI(1)=13:XZI(2)=17:YZI(2)=13
488 XZO(1)=2:YZO(1)=2:XZO(2)=10:YZO(2)=11:XZO(3)=19:YZO(3)=2
489 CALL CHAR(35,"42FF7E6E2C247E66DB7E")!++++++++++++++++++UN PETIT ZOMBIE
490 CALL CHAR(36,"997E7EDB7E2442FF3C18")!+++++++++++++++++++UN PETIT ZIMANGE
491 CZI$="1GBF"
492 CZO$="1bBF"
493 RETURN
494 !
495 ! 17eme TABLEAU
496 !
497 ZI=1:ZO=2
498 XJ=12:YJ=12
499 XZI(1)=19:YZI(1)=19
500 XZO(1)=7:YZO(1)=7:XZO(2)=7:YZO(2)=17
501 CALL CHAR(35,"3C5A665A3C24424242C3")!++++++++++++++++++UN PETIT ZOMBIE
502 CALL CHAR(36,"7EDB7E5A667E3C1824C3")!+++++++++++++++++++UN PETIT ZIMANGE
503 CZI$="1WB"
504 CZO$="1RBF"
505 RETURN
506 !
507 ! 18eme TABLEAU
508 !
509 ZI=2:ZO=3
510 XJ=12:YJ=12
511 XZI(1)=3:YZI(1)=11:XZI(2)=13:YZI(2)=15
512 XZO(1)=3:YZO(1)=19:XZO(2)=15:YZO(2)=5:XZO(3)=19:YZO(3)=19
513 CALL CHAR(35,"7EBDE75A3C5A5A5A99A5")!++++++++++++++++++UN PETIT ZOMBIE
514 CALL CHAR(36,"7EDBFFDBE77E244224E7")!+++++++++++++++++++UN PETIT ZIMANGE
515 CZI$="1RBF"
516 CZO$="1MBF"""
517 RETURN
518 !
519 ! 19eme TABLEAU(C'EST FINI YAN A PLUS)
520 !
521 ZI=3:ZO=6
522 XJ=12:YJ=12
523 XZI(1)=5:YZI(1)=11:XZI(2)=15:YZI(2)=11:XZI(3)=13:YZI(3)=13
524 XZO(1)=2:YZO(1)=2:XZO(2)=10:YZO(2)=2:XZO(3)=18:YZO(3)=2
525 XZO(4)=2:YZO(4)=20:XZO(5)=10:YZO(5)=20:XZO(6)=18:YZO(6)=20
526 CALL CHAR(35,"247EFFC3BDFF24428181")!+++++++++++++++++++UN PETIT ZOMBIE
527 CALL CHAR(36,"997E6E6EE7FF183C66C3")!+++++++++++++++++++++UN PETIT ZIMANGE
528 CZI$="1WBF"
529 CZO$="1YBF"
530 RETURN
531 !
532 ! MORT D'UN ZOMBIE
533 !
534 CALL ZAP(5)
535 FOR ZZ=1 TO ZO
536 IF YZO(ZZ)<>100 THEN LOCATE (YZO(ZZ),XZO(ZZ)):PRINT " "
537 NEXT
538 CALL COLOR(CZI$):LOCATE (YZO(I),XZO(I)):PRINT "$"
539 CALL POKE(259,45):S(J)=S(J)+100
540 YZO(I)=100:ZO=ZO-1
541 IF ZO=0 THEN S(J)=S(J)+100*TA(J):TA(J)=TA(J)+1:GOTO 556
542 GOTO 289
543 !
544 ! DECOMPTE DE VIE
545 !
546 CALL POKE(259,45):V(J)=V(J)-1:CALL SPEECH("L,"&EX$)
547 CALL COLOR("0B")
548 IF V(J)<=0 THEN 565
549 IF NBR=2 AND J=2 THEN J=1:GOTO 226
550 IF NBR=2 AND J=1 THEN J=2:GOTO 226
551 IF NBR=1 THEN 226
552 GOTO 226
553 !
554 ! BONUS
555 !
556 CALL FIN:CALL SPEECH("L,"&EX$):S(J)=S(J)+100*TA(J)
557 IF TA(J)=20 THEN TA(J)=1:S(J)=S(J)+1000*AIE(J):AIE(J)=AIE(J)+3
558 FOR I=2 TO 20
559 LOCATE (I,2):PRINT " "
560 NEXT
561 GOTO 226
562 !
563 ! FIN DU JEU ?
564 !
565 IF NBR=2 AND J=1 THEN J=2:GOTO 567
566 IF NBR=2 AND J=2 THEN J=1
567 IF V(J)=0 THEN 572
568 GOTO 232
569 !
570 ! PERDU
571 !
572 LOCATE (7,28):PRINT " ":LOCATE (15,28):PRINT " ":PER$="PPEERRDDUU"
573 CALL COLOR("0CBHL")
574 LOCATE (12,7):PRINT PER$
575 CALL COLOR("0bBHL"):LOCATE (13,7):PRINT PER$
576 MES$="VOULEZ-VOUS FAIRE UNE AUTRE PARTIE ?(O/N)______"
577 PE=LEN(MES$)
578 FOR I=1 TO PE
579 CALL KEY1(R,J)
580 IF R=79 THEN CALL ZAP(5):GOTO 589
581 IF R=78 THEN CALL ZAP(9):CALL EXEC(50439):END
582 IF LEN(PE$)<22 THEN 585
583 FOR U=1 TO 15:NEXT
584 PE$=SEG$(PE$,2,22)
585 PE$=PE$&SEG$(MES$,I,1)
586 LOCATE (1,1):CALL COLOR("0GB")
587 PRINT PE$:NEXT
588 GOTO 578
589 CLS:CALL COLOR("1WB"):FOR I=1 TO 40:LOCATE (1,I):PRINT "&":NEXT
590 FOR I=2 TO 19:LOCATE (I,40):PRINT "&":NEXT
591 FOR I=40 TO 1 STEP -1:LOCATE (20,I):PRINT "&":NEXT
592 FOR I=19 TO 1 STEP -1:LOCATE (I,1):PRINT "&":NEXT
593 S(1)=0:S(2)=0:V(1)=0:V(2)=0
594 GOTO 142
595 !__________________________________!
596 ! S.P
597 !__________________________________!
598 SUB SON!####################################################
599 FOR I=1 TO 9:READ S,P
600 DATA 30,5,50,5,30,5,50,5,30,10,20,10,10,10,20,10,30,10
601 CALL POKE(258,S,135)
602 FOR B=1 TO P
603 NEXT
604 NEXT
605 CALL POKE(259,45)
606 SUBEND
607 SUB ZAP(M)!###########################
608 FOR I=10 TO 15
609 CALL POKE(258,I,131+M)
610 NEXT
611 CALL POKE(259,45)
612 SUBEND
613 SUB FIN!######################################################
614 FOR I=10 TO 255
615 CALL POKE(258,I,130)
616 NEXT
617 CALL POKE(259,45)
618 SUBEND
619 SUB BEEP(R)!##################################################
620 FOR I=1 TO R
621 FOR J=10 TO 30
622 CALL POKE(258,J,130)
623 NEXT
624 NEXT
625 CALL POKE(259,45)
626 SUBEND
627 SUB CADRE!###################################################
628 CALL COLOR("1WB")
629 FOR I=2 TO 40
630 LOCATE (1,I)
631 PRINT "&":NEXT
632 FOR I=2 TO 20
633 LOCATE (I,40)
634 PRINT "&":NEXT
635 FOR I=40 TO 2 STEP -1
636 LOCATE (20,I)
637 PRINT "&":NEXT
638 FOR I=20 TO 1 STEP -1
639 LOCATE (I,1)
640 PRINT "&":NEXT
641 SUBEND
642 SUB EFF!####################################################
643 FOR I=2 TO 19
644 CALL COLOR("0BB")
645 LOCATE (I,2)
646 PRINT " "
647 NEXT
648 SUBEND
649 SUB JOUEUR!################################################
650 LOCATE (14,8)
651 CALL COLOR("1GB"):CALL FIN
652 PRINT "AB O JK NO RS NO VW"
653 LOCATE (15,8):CALL COLOR("1GB")
654 PRINT "CD LM LM PQ TU PQ XY"
655 SUBEND
656 SUB JOUEURS!################################################
657 CALL COLOR("1GB"):CALL FIN
658 LOCATE (14,7)
659 PRINT "56 O JK NO RS NO VW 12"
660 CALL COLOR("1bB")
661 LOCATE (15,7)
662 PRINT "78 LM LM PQ TU PQ XY 34"
663 SUBEND
664 SUB SCORE(NOM$)!###########################################
665 CALL COLOR("0bBH")
666 LOCATE (2,24)
667 PRINT NOM$
668 CALL COLOR("0WBH")
669 LOCATE (3,24)
670 PRINT NOM$
671 CALL COLOR("0GBH")
672 LOCATE (4,24)
673 PRINT "SCORE:"
674 LOCATE (5,24):CALL COLOR("0bBH")
675 PRINT "SCORE:"
676 CALL COLOR("0CBH")
677 LOCATE (6,24)
678 PRINT "VIE:";
679 CALL COLOR("1YB"):PRINT RPT$("%",V(J))
680 LOCATE (7,24):CALL COLOR("0WBH")
681 PRINT "VIE:":CALL COLOR("0RBH"):LOCATE (20,28):PRINT "e TABLEAU"
682 LOCATE (21,28):PRINT "e TABLEAU":SUBEND
683 SUB BOBO!#################################################
684 CALL COLOR("0bBH")
685 LOCATE (2,24)
686 PRINT "JOUEUR 1":LOCATE (10,24):PRINT "JOUEUR 2"
687 CALL COLOR("0WBH")
688 LOCATE (3,24)
689 PRINT "JOUEUR 1":LOCATE (11,24):PRINT "JOUEUR 2"
690 CALL COLOR("0GBH")
691 LOCATE (4,24):PRINT "SCORE:";S(1)
692 LOCATE (12,24):PRINT "SCORE:";S(2)
693 CALL COLOR("0bBH")
694 LOCATE (5,24):PRINT "SCORE:";S(1)
695 LOCATE (13,24):PRINT "SCORE:";S(2)
696 CALL COLOR("0CBH"):LOCATE (6,24)
697 PRINT "VIE:":CALL COLOR("0bBH")
698 LOCATE (7,24):PRINT "VIE:";:CALL COLOR("1YB"):PRINT RPT$("%",V(J))
699 CALL COLOR("0CBH"):LOCATE (14,24)
700 PRINT "VIE:":CALL COLOR("0bBH"):LOCATE (15,24):PRINT "VIE:";
701 CALL COLOR("1YB"):PRINT RPT$("%",V(J))
702 SUBEND
703 SUB AFFOPT!##############################################
704 TI$(1)=" 11::DDEEBBUUTTAANNTT.................."
705 TI$(2)=" 22::AAMMAATTEEUURR...................."
706 TI$(3)=" 33::PPRROOFFEESSSSIIOONNNNEELL........"
707 FOR I=1 TO 3
708 FOR J=2 TO LEN(TI$(I))
709 CALL COLOR("0GBL")
710 LOCATE (I+8,J):PRINT SEG$(TI$(I),J,1)
711 NEXT
712 CALL SON:NEXT
713 SUBEND
714 !__________________________________!
715 !**********************************!
716 ! LE RECORD A BATTRE EST !
717 ! 213 532 !
718 ! AU NIVEAU PROFESSIONNEL!!! !
719 ! BONNE CHANCE PETIT GLOUTON... !
720 !**********************************!
721 !__________________________________!
Ce listing est uniquement proposé pour un usage privé.
Sans accord écrit préalable, vous n'êtes pas autorisé à le distribuer, le transmettre ou le rediffuser.